tcl命令在Linux中的txt文件中搜索特定单词

Question

我需要编写一个tcl脚本来处理文本文件的行。 该文件看起来像

10.77.33.247    10.77.33.241        rtp 0x26
10.77.33.247    10.77.33.241        rtp 0x26
10.77.33.247    10.77.33.241        rtp 0x26
10.77.33.247    10.77.33.241            0x24
10.77.33.247    10.77.33.241            0x22
10.77.33.247    10.77.33.241            0x21

我需要能够遍历文件，并且对于包含rtp每一行，都将其后的值（例如， 0x26的示例中的0x26 ）存储在变量中，以便在脚本的其他部分中使用。

Answer 1

这是一种（相当底层的）Tcl方法。

set ch [open myfile.txt]
set data [chan read $ch]
chan close $ch

set lines [split [string trim $data] \n]

set res {}
foreach line $lines {
    if {[llength $line] > 3 && [lindex $line 2] eq {rtp}} {
        lappend res [lindex $line 3]
    }
}

如果将“ myfile.txt”替换为数据文件的名称并运行此代码，则会在变量res得到收集后的单词。

---

说明

通常最好使用标准（内置或tcllib）命令，例如glenn jackman的答案中的fileutil::foreachLine 。 但是，如果要一步一步做，Tcl仍然很容易。

第一步是将文件内容存入内存。 也有一个标准命令： fileutil::cat ，但是以下顺序可以做到：

set ch [open myfile.txt]
set data [chan read $ch]
chan close $ch

（这或多或少等效于set data [fileutil::cat myfile.txt] 。）

下一步是将文本分成几行。 修剪文本两端的空格始终是一个好主意，否则，换行符会产生空元素，从而干扰处理。

set lines [split [string trim $data] \n]

在某些情况下，我们可能必须将行拆分为字段列表，但是从示例来看，这些行似乎已经可以用作列表（仅包含空格，字母数字和行为良好的标点符号（例如点）的行） 。

我们需要测试匹配线。 有几种适合您提供的示例数据的替代方法，包括

string match *rtp* $line  ;# match every line that has "rtp" somewhere
[llength $line] > 3       ;# match every line that has more than three columns
[lindex $line 2] eq {rtp} ;# match every line where the third element is "rtp"

我们还需要一种提取所需数据的方法。 如果“ rtp”之后的单词始终位于最后一列，则[lindex $line end]将完成此工作。 如果单词始终在第四列，但可能还有其他列，则[lindex $line 3]更好。

抓住其中的几种选择，可以编写获取指定单词列表的过程

set res {}
foreach line $lines {
    if {[llength $line] > 3 && [lindex $line 2] eq {rtp}} {
        lappend res [lindex $line 3]
    }
}

（用伪代码：得到一个空列表（ res ）；测试每行（使用上面两个测试的组合），从每条匹配的行中提取所需的单词并将其添加到res列表中。）

或者，使用lmap （Tcl 8.6+）

set res [lmap line $lines {
    if {[llength $line] > 3 && [lindex $line 2] eq {rtp}} {
        lindex $line 3
    } else {
        continue
    }
}]

现在，在“ rtp”单词之后出现的所有单词都应为res 。 如果您只想要最后一场比赛，那就是[lindex $res end] 。

文档： 陈 ， 持续 ， 的foreach ， 如果 ， lappend ， LINDEX ， llength ， lmap打开 ， 开放 ， 设置 ， 分裂 ， 串

Answer 2

假设您的文件是foo.txt：

grep "word" foo.txt

Answer 3

grep“ 0x26” file.txt将向您显示所有带有0x26的行。

Answer 4

tcllib有很多优点：

% package require fileutil
1.14.5
% fileutil::foreachLine line "file" {
    if {[string match {*rtp*} $line]} {
        lappend values [lindex [split $line] end]
    }
}
% puts $values
0x26 0x26 0x26

Answer 5

下面的代码用于从文件（以cotes（“”））获取文本：

 proc aifWebcamInitVideo {} { variable devicePath "c:/testfile.txt" #ffmpeg command to get the device name connected to system exec ffmpeg -list_devices true -f dshow -i dummy >& $devicePath & after 4000 ;# wait of 4 seconds so that device can be selected. set files [glob $aif::LogRootDir/*] ;# Look for all the files. foreach file $files { set fileName $devicePath if {[string match $fileName $file ] } { ;# this if statement check currently captured video with the files present in directory. set file [open $devicePath ] ;# open the file set file_device [read $file] set data [split $file_device "\\n"] ;# divides the open file into lines. foreach line $data { if {[regexp {"([^""]*)"} $line -> substring]} { ;# check for the quotes to retrieve the device connected to system. set result $substring lappend cameraList $result ;# makes the list of devices. set camera [lindex $cameraList 0] } } close $file break } } #values passed to FFMPEG command. variable TableCamera $camera puts "Device selected for Video capture is : $TableCamera" ;# gets the first device from the list }