使用多个条件在Excel中排名

Question

例如，我需要根据总分（ C列）创建少数学生的绩效列表，然后在数学（ B栏）中创建更高的分数 -

A        B  C   D
-------------------------
Student1 80 220 1
Student2 88 180 3
Student3 90 180 2

预期的绩效位置在D栏中给出。

我可以使用RANK函数，但我只能为一列（总数）执行此操作。 如果多个学生的总数相等，我找不到任何解决方法。

Answer 1

您可以在D1中尝试这个

=COUNTIF($C$1:$C$99,">"&C1)+1+SUMPRODUCT(--($C$1:$C$99=C1),--($B$1:$B$99>B1))

然后复制/填写。 如果这有帮助，请告诉我。

说明

您的第一个标准位于C列 ，第二个标准位于B列 。 基本上，首先它计算的条目数（$ C $ 1：$ C $ 99）大于条目本身（$ C1） 。 对于排名中的第一个，您将得到零 ，因此您需要为每个结果（+1）添加1 。 在此之前，如果两次具有相同的值，您将获得重复的排名。
因此，您需要添加另一个参数以根据第二个条件执行一些额外的计算：
要解决这种情况，你需要sumproduct两个数组公式并将结果添加到前一个参数，目标是找到与$ C $ 1相同的条目数：$ C $ 99 = C1并且有一个第二个标准栏中的较大值$ B $ 1：$ B $ 99> B1 ：

你添加-将TRUE和FALSE转换为0秒和1秒，以便您可以将它们相乘：
SUMPRODUCT(--($C$1:$C$99=C1),--($B$1:$B$99>B1))
第一个数组是看你在第一个标准中有多少联系。 第二个数组是查找比条目本身更大的值的数量。

请注意，您可以根据需要向列中添加任意数量的条目，但请记住更新公式中的范围，当前设置为99 ，您可以将其扩展为所需的行数。

Answer 2

有时， 辅助列将提供快速且计算有效的解决方案。 将数学标记作为小数添加到总标记应该产生一个将根据您的标准排名的数字。 在右侧未使用的列中，在第2行中使用此公式，

=C2+B2/1000

必要时填写。 您现在可以在此帮助列上使用常规RANK函数 ，例如=RANK(D2, D$2:D$9)作为您的排名序数。

Answer 3

非常简单（或者，至少比最佳答案提供的更简单）“数学”解决方案：与权重进行线性组合。 做点什么

weighted_marks = 10*colC + colB

然后使用简单的排名函数对加权标记进

它确实解决了您的问题，提升了您所需的排名。

Answer 4

如果您不想限制标准中使用的行数或数字，可以扩展Jeeped的方法 。 您可以在单元格D2到L2中使用以下公式，假设有三个条件，第一个在A列中，第二个在B列中，第三个在C列中：

=RANK($A2,$A:$A,1)
=RANK($B2,$B:$B,1)
=D2*2^27+E2
=RANK(F2,F:F,1)
=RANK($C2,$C:$C,1)
=G2*2^27+H2
=RANK(I2,I:I,1)
=J2*2^27-ROW()
=RANK(K2,K:K,0)

公式必须被复制下来。 结果在列L中。使用行号断开连接。

如果您想添加第四个标准，可以在完成上述公式后执行以下操作：

1. 在C列和D列之间添加新标准。
2. 在第I列和第J列之间插入三个新列。
3. 将列G：I复制到新列J：L。
4. 将列G复制到M列，覆盖其内容。
5. 更改L列中的公式以指向新标准。

公式中使用的因子2^27平衡了双精度数中可用的53位精度 。 这足以涵盖当前版本的Excel的行限制。