Fortran 2003-2008中是否有替代GETCWD（）的方法

Question

GNU Fortran编译器的GNU扩展提供了子程序GETCWD() ，它获取当前工作目录。 但是，我的代码也必须可移植到ifort和nagfor编译器，并且我使用F2003功能。

那么，F2003及更高版本的GETCWD()有替代品吗？

我在这里有标准，但它相当大，我现在已经经历了一段时间并且没有找到任何有用的东西......

Answer 1

如评论中所述，您可以使用标准Fortran的get_environment_variable （例如F2008 13.7.67）。 此示例程序查询$PWD的值，该值应包含shell在调用可执行文件时所在的目录。

program test
 implicit none
 character(len=128) :: pwd
 call get_environment_variable('PWD',pwd)
 print *, "The current working directory is: ",trim(pwd)
end program

它的输出：

casey@convect code % pwd
/home/casey/code
casey@convect code % so/getpwd 
 The current working directory is: /home/casey/code

这是标准的Fortran，但它的可移植性将仅限于设置此变量的Unix和类Unix shell。

另一种选择虽然标准但丑陋（在我看来）是使用execute_command_line来运行一个命令，可以将工作目录输出到临时文件（例如pwd > /tmp/mypwd ），然后读取该文件。

Answer 2

您还可以使用ISO_C_Binding并调用相应的C函数：

cwd.c：

#ifdef _WIN32
/* Windows */
#include <direct.h>
#define GETCWD _getcwd

#else
/* Unix */
#include <unistd.h>
#define GETCWD getcwd

#endif

void getCurrentWorkDir( char *str, int *stat )
{
  if ( GETCWD(str, sizeof(str)) == str ) {
    *stat = 0;
  } else {
    *stat = 1;
  }
}

test.F90：

program test
 use ISO_C_Binding, only: C_CHAR, C_INT
 interface
   subroutine getCurrentWorkDir(str, stat) bind(C, name="getCurrentWorkDir")
     use ISO_C_Binding, only: C_CHAR, C_INT
     character(kind=C_CHAR),intent(out) :: str(*)
     integer(C_INT),intent(out)         :: stat
    end subroutine
  end interface
  character(len=30)   :: str
  integer(C_INT)      :: stat

  str=''
  call getCurrentWorkDir(str, stat)
  print *, stat, trim(str)

end program

此代码适用于Windows和Unix派生（Linux，OSX，BSD等）

Answer 3

接受的答案包含两个错误（它将错误的值作为字符串的长度传递给GETCWD ，并留在C_NULL_CHAR ）。 这个答案纠正了这些错误，使界面更易于从Fortran中使用。

基本思路是一样的：使用C调用getcwd或_getcwd ，并使用Fortran的C互操作性功能调用C包装器。 在Fortran端，包装器子例程用于处理字符串长度，因此不必显式传递。

此外， C_INT和C_CHAR不必与Fortran端需要的默认整数和默认字符相同（尽管在实践中我不知道任何C_CHAR和默认字符不同的系统）。 包装器也可以转换它们。 此外，从C返回的字符串包含终止C_NULL_CHAR ，必须删除该字符串才能使字符串在Fortran端可用。

C代码：

#ifdef _WIN32
#include <direct.h>
#define GETCWD _getcwd
#else
#include <unistd.h>
#define GETCWD getcwd
#endif

/* Return 0 on success, 1 on error. */
int getCWDHelper(char *str, int len)
{
    return GETCWD(str, len) != str;
}

Fortran代码：

module cwd
    use iso_c_binding, only: C_INT, C_CHAR, C_NULL_CHAR
    implicit none
    private
    public :: getCWD

    interface
        function getCWDHelper(str, len) bind(C, name="getCWDHelper")
            use iso_c_binding, only: C_INT, C_CHAR
            integer(kind=C_INT) :: getCWDHelper
            character(kind=C_CHAR), intent(out) :: str(*)
            integer(kind=C_INT), value :: len
        end function getCWDHelper
    end interface

contains

    ! Writes the current working directory path into str.
    ! Returns 0 on success, or 1 on error.
    function getCWD(str)
        integer :: getCWD
        character(*), intent(out) :: str

        integer :: i, length
        character(len=len(str), kind=C_CHAR) :: str_copy

        ! Call the C helper, passing the length as the correct int kind
        getCWD = getCWDHelper(str_copy, len(str_copy, kind=C_INT))

        if (getCWD /= 0) then
            str = '' ! Error, clear the string
            return
        end if

        ! Copy the C_CHAR string to the output string,
        ! removing the C_NULL_CHAR and clearing the rest.
        length = index(str_copy, C_NULL_CHAR) - 1
        do i = 1, length
            str(i:i) = char(ichar(str_copy(i:i)))
        end do
        str(length+1:) = ''
    end function getCWD

end module

测试代码：

program test
    use cwd, only: getCWD
    implicit none

    character(len=255) :: path
    integer :: error

    error = getCWD(path)

    print *, error
    if (error == 0) print *, path
end program

使返回值可分配和循环以获得足够的大小留给读者练习。