List（of T）的语法类型：ListBox的命名/转换DragDrop

Question

我试图为拖放ListBox.Selecteditems创建一个通用例程，从源中获取ListBox.SelectedItems并创建一个List（T）。 为此，我需要能够获取基础ListBox.SelectedValue的Type，并相信我能够使用以下行来实现：

Dim lbxType As Type = (sender.SelectedValue).GetType

这是上下文中的子例程：

Private Sub ListBox1_MouseDown(ByVal sender As System.Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles ListBox1.MouseDown
  If ListBox1.SelectedItems.Count = 0 OrElse e.Button <> Windows.Forms.MouseButtons.Right Then Return
  Dim lbxType As Type = (sender.SelectedValue).GetType
  Dim selItems As New List(Of lbxType)   <- FAILS! it fails here - will not compile
  {…more code…}
End Sub

显然，除此之外，我不知道如何创建如上代码所示的那种类型的List（Of T）的语法（请参阅标记为“ FAILS”的行）。 我知道我总是可以得到一个字符串TypeName（），然后执行一个Select / Case，但是我希望有一种更多的“模块化”方式。 任何帮助或指示将不胜感激。

非常感谢你！

编辑结果＃1

Private Sub LbxTestDragStart(ByVal sender As System.Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles ListBox1.MouseDown, ListBox3.MouseDown
    Dim lbx = DirectCast(sender, ListBox)
    If lbx.SelectedItems.Count = 0 OrElse e.Button <> Windows.Forms.MouseButtons.Right Then Return
    Dim dragLst = CType(GetType(List(Of )).
        MakeGenericType(lbx.SelectedItems(0).GetType()).
        GetConstructor(Type.EmptyTypes).
        Invoke(Nothing), IList)
    For Each si In lbx.SelectedItems
        dragLst.Add(si)
    Next
    lbx.DoDragDrop(dragLst, DragDropEffects.Copy)
End Sub

Private Sub Lbx_DragEnter(ByVal sender As System.Object, ByVal e As System.Windows.Forms.DragEventArgs) Handles ListBox2.DragEnter, ListBox3.DragEnter
    Dim lbx = DirectCast(sender, ListBox)
    'we assume only one type of format in each listbox
    Dim fmt = e.Data.GetFormats(0)
    Dim fmtName As String = TypeName(e.Data.GetData(fmt(0))(0))
    e.Effect = DragDropEffects.None
    'id specific target listbox to set DD effects as this is a multi-purpose sub
    'in this select case, for testing, listbox3 is noticeably absent
    Select Case lbx.Name
        Case "ListBox1"
            'do something if ListBox1
        Case "ListBox2"
            If fmtName = "ClientLocation" Then e.Effect = DragDropEffects.Copy
    End Select
End Sub

Private Sub Lbx_DragDrop(ByVal sender As System.Object, ByVal e As System.Windows.Forms.DragEventArgs) Handles ListBox2.DragDrop, ListBox3.DragDrop
    Dim lbx = DirectCast(sender, ListBox)
    Dim fmt = e.Data.GetFormats(0)
    Dim fmtName As String = TypeName(e.Data.GetData(fmt(0))(0))
    'setup for processing of dropped items
    Select Case lbx.Name
        Case "ListBox2"
            If fmtName = "ClientLocation" Then
                For Each item In e.Data.GetData(fmt(0))
                    lbx.Items.Add(item)
                Next
            End If
    End Select
End Sub

Answer 1

正如我在评论中所述，拖放之间的时间太短，以至于真的不值得创建一个通用列表。 放置目标应检查放置的类型，以便仅接受ClientLocation项目， CircusClown接受CircusClown项目。

也就是说，这是仍然避免动态创建列表的方法（ Animal是您的ClientLocation的Type代表）：

Private dragList As List(Of Animal)

Private Sub lb_MouseMove(sender ...
    If lbMouseDown Then

        dragList = New List(Of Animal)
        For Each a As Animal In lb.Items
            dragList.Add(a)
        Next

        lb.DoDragDrop(dragList, DragDropEffects.Copy)
        ...

您的代码假装好像不知道ListBox中的类型是什么。 如果那可能是因为它可能是几种类型之一-也许内容发生了变化（？），那么您必须求助于Reflection ：

' get the Type for a List(of T)
Dim genType = GetType(List(Of ))
' get the type in the listbox
Dim t As Type = lb.SelectedItems(0).GetType() 'GetType(Animal) 
' get the "combined" type for List(of ) + ListType
Dim LType = genType.MakeGenericType(t)     ' == List(of Animal)

此时，您可以采用两种方法：

' METHOD 1: using a ctor
Dim ctor As ConstructorInfo = LType.GetConstructor(Type.EmptyTypes)
Dim theList = CType(ctor.Invoke(Nothing), IList)

' METHOD 2: using System.Activator:
Dim theList = CType(Activator.CreateInstance(LType), IList)

' EITHER WAY, xfer items - see note
For Each aa In lb.SelectedItems
    theList.Add(aa)
Next
lb.DoDragDrop(theList, DragDropEffects.Copy)

出于说明目的将其格式化。 您可以使用GetConstructor版本链接方法，并避免所有临时类型var：

Dim dragLst = CType(GetType(List(Of )).
    MakeGenericType(lb.SelectedItems(0).GetType()).
    GetConstructor(Type.EmptyTypes).
    Invoke(Nothing), IList)

注意：通常，您需要在DragDrop启动时添加鼠标悬停的项目-用户可能会期望如此。 该项目可能不是SelectedItems的一部分，他们可能只想拖动该项目。 这意味着在eX，eY下查找项目

为了简单起见，该代码仅使用SelectedItems 。