如何确保批量分配足够的磁盘空间？

Question

有谁知道是否有可能确保磁盘上具有批处理功能的服务器上有足够的空间？

我有一个循环的批处理脚本，在此我想添加一个部分来确保磁盘上有足够的空间，如果没有，则会给我一条消息。 这样，很容易解释：

Check diskspace
 If below 10mb free space
  echo low diskspace (& probably delete temp files or something)
   else continue

谢谢你的帮助！

Answer 1

这使用dir命令的输出来检索可用空间。 所有测试都在一个子例程中进行，该子例程接收要检查的“驱动器”以及所需的字节数作为参数。 退出时，如果没有足够的可用空间，则会引发错误级别。

批处理文件中的算术限制为2 ^ 31个有符号整数，因此要处理大于2147483647的值并与2GB以上的存储单元一起使用，需要更多代码。 为避免这种情况，所有信息都以字节表示/检索，以字符串填充和比较。

@echo off
    setlocal enableextensions disabledelayedexpansion

    call :checkFreeSpace d: 123456789 && echo OK || echo No space

    call :checkFreeSpace "\\10.0.0.1\c$" 2000000000
    if errorlevel 1 (
        echo No space
    ) else (
        echo OK
    )

    goto :eof

:checkFreeSpace drive spaceRequired
    setlocal enableextensions disabledelayedexpansion
    set "pad=0000000000000000000000000"
    set "required=%pad%%~2"
    for %%d in ("%~1\.") do for /f "tokens=3" %%a in ('
        dir /a /-c "%%~fd" 2^>nul ^| findstr /b /l /c:"  " 
    ') do set "freeSpace=%pad%%%a"
    if "%freeSpace:~-25%" geq "%required:~-25%" exit /b 0
    exit /b 1

注意 ：此方法有一个警告。 如果指示的目标是驱动器根目录，并且其中没有任何文件/文件夹，则dir命令将找不到任何要列出的内容，并且可用空间将不包含在其输出中，从而使测试失败，因为可用空间将是0