使用Delphi + Jedi，当设备“过快”发送USB数据时会丢失

Question

使用Jedi库中的Delphi XE2和TJvHidDevice类，我设法与USB设备（ pic32mx7板，代码在其上运行）成功通信。 “发送请求，等待单个响应”的通常方式起作用。

问题在于命令会导致大量连续响应。 如果这些响应是由设备尽快发送的，或者即使我在它们之间添加了5ms之类的小延迟，我也会丢失数据包（报告？帧？）。 OnDeviceData事件似乎并没有为所有事件触发。 如果我在设备代码中添加较大的延迟，则问题将消失。

我使用USBPcap程序捕获USB数据并将其转储到文件中，一旦在WireShark中将其打开，该文件将包含该设备发送的所有数据（我发送255个数据包作为测试，所有零和一个“ 1”移位它在每个数据包中的位置）。 因此，我认为设备和Windows都在做自己的工作。

为了确保我的Delphi代码没有错误，我尝试了Jedi示例项目“ DevReader”（这是main.pas代码 ），该项目在屏幕上转储数据，并且也丢失了数据包。

我觉得网上应该有更多有关绝地的USB类的信息，但是我很难找到它。

我可以通过汇总/压缩设备的响应来避免此问题，但仍然想知道发生了什么。

编辑：

1. 从控制台应用程序中尝试过：数据包不再丢失。
2. 修改了Jedi演示应用程序，使其仅对接收到的数据包进行计数并更新屏幕上的计数器标签（无强制窗口重绘）-没有丢失的数据包。
3. 在OnData事件中添加了sleep（1）-没有丢失的数据包。
4. 在OnData事件中添加了sleep（2）-再次丢失数据包。

看起来读取数据的Jedi线程一定不能因任何处理而延迟-是否不应该对正在进行的数据缓冲（由Windows进行）以允许这种类型的处理延迟？ 从数据包丢失的“模式”来看，似乎有缓冲，但这是不足的，因为我可以接收到30个数据包，然后丢失5个，然后再接收20个，依此类推。

我将修改代码以复制数据并尽快退出OnData事件，以使线程具有最少的“停机时间”，并报告结果。

Answer 1

由于问题的原因似乎与USB读取线程被Synchronise阻止的时间有关，即由主线程执行的数据处理，因此我对线程代码进行了更改（（TJvHidDeviceReadThread类，JvHidControllerClass.pas单元）。 使用此单元及其包含的类的任何代码都应在不做任何修改的情况下仍然可以正常工作，而公共部分没有任何更改。

新行为：每次读取数据时，都会将其放置在线程安全列表中。 现在，它使用Queue代替了Synchronize，但前提是尚未将其排队。 排队方法从线程安全列表读取，直到它为空。 它为列表中的每个缓冲报表触发一个事件（与旧代码中的事件相同）。 一旦列表为空，将重置“已排队”标志，下一次读取将再次导致排队。

到目前为止，在测试中我没有遇到丢失的数据包。

线程类已扩展：

  TJvHidDeviceReadThread = class(TJvCustomThread)
  private
    FErr: DWORD;

    // start of additions
    ReceivedReports : TThreadList;
    Queued: boolean;
    procedure PushReceivedReport(const bytes: array of byte; const NumBytesRead: cardinal);
    function PopReceivedReport(var ReportID: byte; var ReportBytes: TBytes): boolean;
    procedure FlushBuffer;
    // end of additions

    procedure DoData;
    procedure DoDataError;
    constructor CtlCreate(const Dev: TJvHidDevice);
  protected
    procedure Execute; override;
  public
    Device: TJvHidDevice;
    NumBytesRead: Cardinal;
    Report: array of Byte;
    constructor Create(CreateSuspended: Boolean);
    //added destructor:
    destructor Destroy; override;
  end;

在实施部分中，进行了以下修改：

constructor TJvHidDeviceReadThread.CtlCreate(const Dev: TJvHidDevice);
begin
  inherited Create(False);
  // start of changes
  ReceivedReports := TThreadList.Create; 
  // end of changes
  Device := Dev;
  NumBytesRead := 0;
  SetLength(Report, Dev.Caps.InputReportByteLength);
end;

procedure TJvHidDeviceReadThread.Execute;
...
...
...
    //replaced: Synchronize(DoData); with:
    PushReceivedReport (Report, NumBytesRead);
...

并且添加了以下内容：

type

TReport = class
  ID: byte;
  Bytes: TBytes;
end;

destructor TJvHidDeviceReadThread.Destroy;
var
  l: TList;
begin
  RemoveQueuedEvents (self);
  try
    l := ReceivedReports.LockList;
    while l.Count>0 do
      begin
        TReport(l[0]).Free;
        l.Delete(0);
      end;
  finally
    ReceivedReports.UnlockList;
    FreeAndNil (ReceivedReports);
  end;

  inherited;
end;

procedure TJvHidDeviceReadThread.FlushBuffer;
var
  ReportID: byte;
  ReportBytes: TBytes;
begin
  while PopReceivedReport (ReportID, ReportBytes) do
        Device.OnData(Device, ReportID, ReportBytes, length(ReportBytes));
end;

function TJvHidDeviceReadThread.PopReceivedReport(var ReportID: byte; var ReportBytes: TBytes): boolean;
var
  l: TList;
  rep: TReport;
begin
  l := ReceivedReports.LockList;
  rep := nil;
  try
    result := l.Count>0;
    if result
      then
        begin
          rep := l[0];
          l.Delete(0);
        end
      else Queued := false;
  finally
    ReceivedReports.UnlockList;
  end;

  if result then
    begin
      ReportID := rep.ID;
      SetLength(ReportBytes, length(rep.Bytes));
      System.move (rep.Bytes[0], ReportBytes[0], length(rep.Bytes));
      rep.Free;
    end;
end;

procedure TJvHidDeviceReadThread.PushReceivedReport(const bytes: array of byte; const NumBytesRead: cardinal);
var
  rep: TReport;
begin
  rep := TReport.Create;
  setlength (rep.Bytes, NumBytesRead-1);
  rep.ID := Bytes[0];
  System.move (Bytes[1], rep.Bytes[0], NumBytesRead-1);

  // explicitely lock the list just to provide a locking mechanism for the Queue flag as well
  ReceivedReports.LockList;
  try
    if not Queued then
      begin
        Queued := true;
        Queue (FlushBuffer);
      end;
    ReceivedReports.Add(rep);
  finally
    ReceivedReports.UnlockList;
  end;
end;