如何强制Clips遵守规则，直到完全完成数据而没有冗余？

Question

我想让片段按照我的命令解雇规则。

我使用了“状态”模板，通过在触发每个规则后修改广告位“状态”来确保规则将按照我的命令执行（冲突解决）。 但是，剪辑会在第一次执行规则后修改“状态”，而不是在使用rule.fish捕获所有接受的数据之后修改“状态”。因此，我使用了“更改”模板和规则“ callChange”来为我更改“状态”。 但是，仍然是同样的问题。 我尝试了“显着性”，但是它永远做第一个被解雇的规则，并且不会以“显着性”较低的规则被其他解雇者使用。

任何帮助请放心我的代码：

    (deftemplate laptop(slot name)(slot price)(slot usagefor )(slot description))
    (deftemplate find_laptops  (slot price)(slot usagefor ))
    (deftemplate range(slot min)(slot max))
    (deftemplate state(slot status))
    (deftemplate change(slot newStatus))

    (deffacts laptops
    (laptop(name k53e)(price 200)(usagefor homeandoffice)(description 2.1i3_6gb_500gb_intel_2.2kg))
    (laptop(name x205ta)(price 200)(usagefor homeandoffice)(description 1.3atom_2gb_320ssd_intel_1.5kg))
    (laptop(name n550gk)(price 800)(usagefor gamingandprogramming)(description 2.4i7_8gb_1t_nvidia850_2.2kg))
    (state(status 1))
    (change(newStatus notFinish)))

    (defrule callChange (declare (salience 10))
    ?c<-(change(newStatus ?newStatus))
    ?s<-(state(status ?status))=>
    (modify ?c (newStatus notFinish))
    (modify ?s (status(+ ?status 1))
    ))

    (defrule get_info_laptop (declare (salience 50))
    ?s<-(state(status 1))
    ?c<-(change(newStatus ?newStatus))  =>

    (printout t "enter usagefor" crlf) (bind ?usagefor (read))
    (printout t "enter price " crlf) (bind  ?price (read))
    (assert(find_laptops(price ?price)(usagefor ?usagefor)))
    (modify ?c (newStatus Finish))
    )

    (defrule find_laptop_res (declare (salience 100))
    ?s<-(state(status 2))
    ?c<-(change(newStatus ?newStatus))
    (find_laptops(price ?price)(usagefor ?usagefor )) 
    (laptop(name ?name)(price ?price)(usagefor ?usagefor )(description ?description)) =>  
    (printout t " the name is " ?name " and the description " ?description" the best laptop is " ?name  crlf)
    (modify ?c (newStatus Finish)))

Answer 1

您想要的确切行为从您的问题中还不清楚，但这是一种用于查询用户，打印所有结果然后确定是否应该执行其他查询的技术。

CLIPS> (clear)
CLIPS> 
(deftemplate laptop 
   (slot name)
   (slot price)
   (slot usagefor)
   (slot description))
CLIPS> 
(deftemplate find_laptops
   (slot price)
   (slot usagefor))
CLIPS> 
(deffacts laptops
   (laptop (name k53e) (price 200) (usagefor homeandoffice) (description 2.1i3_6gb_500gb_intel_2.2kg))
   (laptop (name x205ta) (price 200) (usagefor homeandoffice) (description 1.3atom_2gb_320ssd_intel_1.5kg))
   (laptop (name n550gk) (price 800) (usagefor gamingandprogramming) (description 2.4i7_8gb_1t_nvidia850_2.2kg)))
CLIPS>    
(defrule get_info_laptop 
   (not (find_laptops))
   =>
   (printout t "Enter usagefor ") 
   (bind ?usagefor (read))
   (printout t "Enter price ") 
   (bind  ?price (read))
   (assert (find_laptops (price ?price) (usagefor ?usagefor))))
CLIPS> 
(defrule find_laptop_res 
   (find_laptops (price ?price) (usagefor ?usagefor )) 
   (laptop (name ?name) (price ?price) (usagefor ?usagefor) (description ?description)) 
   =>  
   (printout t " The name is " ?name " and the description " ?description " the best laptop is " ?name  crlf))
CLIPS> 
(defrule find_laptop_none
   (find_laptops (price ?price) (usagefor ?usagefor )) 
   (not (laptop (price ?price) (usagefor ?usagefor)))
   =>  
   (printout t " No matching laptops"  crlf))
CLIPS>    
(defrule done_laptop_res 
   (declare (salience -10))
   ?f <- (find_laptops) 
   =>  
   (printout t "Search again? ")
   (bind ?answer (read))
   (if (member$ (lowcase ?answer) (create$ y yes))
      then
      (retract ?f)))
CLIPS> (reset)
CLIPS> (run)
Enter usagefor gamingandprogramming
Enter price 800
 The name is n550gk and the description 2.4i7_8gb_1t_nvidia850_2.2kg the best laptop is n550gk
Search again? yes
Enter usagefor homeandoffice
Enter price 200
 The name is x205ta and the description 1.3atom_2gb_320ssd_intel_1.5kg the best laptop is x205ta
 The name is k53e and the description 2.1i3_6gb_500gb_intel_2.2kg the best laptop is k53e
Search again? yes
Enter usagefor homeandoffice
Enter price 300
 No matching laptops
Search again? no
CLIPS> 

或者，使用事实查询功能代替与规则的模式匹配：

CLIPS> (clear)
CLIPS> 
(deftemplate laptop 
   (slot name)
   (slot price)
   (slot usagefor)
   (slot description))
CLIPS> 
(deffacts laptops
   (laptop (name k53e) (price 200) (usagefor homeandoffice) (description 2.1i3_6gb_500gb_intel_2.2kg))
   (laptop (name x205ta) (price 200) (usagefor homeandoffice) (description 1.3atom_2gb_320ssd_intel_1.5kg))
   (laptop (name n550gk) (price 800) (usagefor gamingandprogramming) (description 2.4i7_8gb_1t_nvidia850_2.2kg)))
CLIPS>    
(deffunction run-query ()
   (printout t "Enter usagefor ") 
   (bind ?usagefor (read))
   (printout t "Enter price ") 
   (bind  ?price (read))
   (bind ?results 
      (find-all-facts ((?f laptop)) 
         (and (eq ?f:usagefor ?usagefor)
              (eq ?f:price ?price))))
   (if (= (length$ ?results) 0)
      then
      (printout t " No matching laptops"  crlf)
      else
      (progn$ (?r ?results)
         (printout t " The name is " (fact-slot-value ?r name)
                     " and the description " (fact-slot-value ?r description)
                     " the best laptop is " (fact-slot-value ?r name)  crlf)))
   (printout t "Search again? ")
   (bind ?answer (read))
   (if (member$ (lowcase ?answer) (create$ y yes))
      then
      (return TRUE)
      else
      (return FALSE)))
CLIPS>       
(defrule get_info_laptop 
   =>
   (while (run-query) do))
CLIPS> (reset)
CLIPS> (run)
Enter usagefor gamingandprogramming
Enter price 800
 The name is n550gk and the description 2.4i7_8gb_1t_nvidia850_2.2kg the best laptop is n550gk
Search again? yes
Enter usagefor homeandoffice
Enter price 200
 The name is k53e and the description 2.1i3_6gb_500gb_intel_2.2kg the best laptop is k53e
 The name is x205ta and the description 1.3atom_2gb_320ssd_intel_1.5kg the best laptop is x205ta
Search again? y
Enter usagefor homeandoffice
Enter price 300
 No matching laptops
Search again? no
CLIPS>