在将控件添加到表单之前，设置添加的datagridview的列可见性（属性）

Question

GD全部，

我有一个相当简单的表单循环，该表单添加了用于选择记录的标签页。 在添加的选项卡上，它插入一个DataGridView来显示每个选项卡标识符所选择的记录。

为了做到这一点，我创建了以下代码：

    For Each r As DataRow In tnkTable.Rows

        Dim tmpTableAdapter As New RD_BWMDataSetTableAdapters.tblEventRegisterTableAdapter
        Dim newTab As New TabPage()
        Dim newGrid As New DataGridView() With {.Location = New Point(6, 6), .Width = 800}
        Dim newBindingSource As New BindingSource()
        Dim newDataview As DataView

        newDataview = tmpTableAdapter.GetData.AsDataView

        With newDataview
            .Sort = "utcDateTime DESC"
            .RowFilter = "IdTank = " & r("Id").ToString
        End With

        With newGrid
            .Name = "dg" & r("tankShortCode").ToString
            .DataSource = newDataview
        End With

        With newTab
            .Name = r("tankShortCode").ToString
            .Text = r("tankShortCode").ToString
            .Controls.Add(newGrid)
        End With

        With Me.tabTankTable

            .TabPages.Add(newTab)

        End With

        'End If
    Next

本质上，这将在每个选项卡页面上插入正确的DataGridView，并将相关过滤器应用于DataGridView。

但是，挑战在于，我想隐藏每个datagridview的前3列。 但是，当我尝试在DataGridView对象（即“ newGrid”）上执行此操作时，它不允许我这样做，因为“ newGrid”对象似乎没有任何列？

我尝试了几种途径，但未能产生预期的结果。

我认为有两种选择：

1. 找出为什么尽管有包含正确数据的数据源，“ newGrid”对象却没有列（更新/刷新??）
2. 在添加实际控件后，捕获添加的控件并修改列。 我也尝试过此操作，但是出现列索引错误，表明Control对象也没有列。

但是，在查看表单时，所有dgViews中都包含适当的数据，并且所有列中都有？

有什么建议么 ？

马丁·吐温

Answer 1

由于列是自动生成的，因此将在设置.DataSource之后添加它们。
添加DataBindingComplete事件处理程序，您可以在其中隐藏/删除列

With newGrid
    .Name = "dg" & r("tankShortCode").ToString
    .DataSource = newDataview
    AddHandler .DataBindingComplete, AddressOf Me.DataGridView_DataBindingComplete
End With

创建事件处理程序

Private Sub DataGridView_DataBindingComplete(sender As Object, e AsDataGridViewBindingCompleteEventArgs)
    Dim dgv As DataGridView = TryCast(sender, DataGridView)
    If dgv Is Nothing Then Exit Sub
    For Each column As DataGridViewColumn In dgv.Columns.Cast(Of DataGridViewColumn).Take(3)
        column.Visible = false
    Next

End Sub