WebGL基本着色器混淆

Question

我正在学习WebGL着色器，但是它们使我感到困惑。 这是我到目前为止所得到的：

<script type="x-shader/x-vertex" id="vertexshader">

    #ifdef GL_ES
        precision highp float;
    #endif

    void main()
    {
        gl_Position = projectionMatrix * modelViewMatrix * vec4( position, 1.0 );
    }

</script>

<script type="x-shader/x-fragment" id="fragmentshader">

    #ifdef GL_ES
        precision highp float;
    #endif

    void main()
    {
        gl_FragColor    = vec4(1.0, 0.0, 1.0, 1.0);
    }

</script>

到目前为止，一切顺利，它可以编译，并且我得到一个粉红色的立方体。

现在，混乱就解决了。 据我了解，片段着色器用于修改颜色，顶点着色器用于修改形状。

我不明白gl_FragColor是否设置整个对象的颜色，还是按某种顺序绘制，以便可以操纵着色器中的坐标，例如使其随机着色？

如果是这样，它怎么知道什么形状和着色顺序？

另外，如果只想使用fragmenthader，为什么需要定义顶点着色器，默认的gl_Position行有什么作用，为什么需要它？

到目前为止，我尝试过的所有GLSL教程均无法正常运行，并且three.js无法编译。 有什么建议从哪里开始？

Answer 1

这个问题很广泛。

假设您做这样的事情：

var myRenderer = new THREE.WebGLRenderer();
var myScene = new THREE.Scene();
var myTexture = new THREE.Texture();
var myColor = new THREE.Color();
var myMaterial = new THREE.MeshBasicMaterial({color:myColor, map:myTexture});
var myColoredAndTexturedCube = new THREE.Mesh( new THREE.CubeGeometry(), myMaterial); 
var myCamera = new THREE.Camera();

如果连接所有这些，您将在屏幕上呈现一个多维数据集，并且如果提供颜色和纹理，它将同时显示这两种颜色（用颜色着色的纹理）。

虽然很多事情发生在幕后。 Three.js将通过WebGL API向gpu发布指令。 这些是非常低级的调用，例如“占用此内存块并准备好绘制”，“准备此着色器以处理此内存块”，“为此调用设置混合模式”。

我不明白gl_FragColor是否设置整个对象的颜色，还是按某种顺序绘制，以便可以操纵着色器中的坐标，例如使其随机着色？

如果是这样，它怎么知道什么形状和着色顺序？

您应该阅读一些有关渲染管道的信息，也许您一开始可能不会完全理解它，但是可以肯定地澄清一些事情。

gl_FragColor设置缓冲区中像素的颜色（可以是屏幕，也可以是屏幕外纹理）。 是的，它为“整个对象”设置颜色，但是整个对象可以是粒子云（您可以解释多个对象）。 您可以有一个10x10的立方体网格，每个立方体的颜色不同，但是仍然通过一个绘制调用（一个对象）进行渲染。

所以回到你的shder：

//you dont see this, but three injects this for you, try intentionally adding a mistake to your shader, when your debugger complains, youll see the entire shader and these lines in it

uniform mat4 projectionMatrix; //one mat4 shared across all vertices/pixels
uniform mat4 modelViewMatrix; //one mat4 shared across all vertices/pixels
attribute vec3 position;  //actual vertex, this value is different in each vertex


//try adding this
varying vec2 vUv;

void main()
{

    vUv = uv;  //uv, just like position, is another attribute that gets created for you automatically, this way we are sending it to the pixel shader through the varying vec2 vUv.


    //this is the transformation 
    //projection matrix is what transforms space into perspective (vanishing points, things get smaller as they get further away from the camera)
    //modelViewMatrix are actually two matrices, viewMatrix, which is also part of the camera (how is this camera rotated and moved compared to the rest of the world)
    //finally the modelMatrix - how big is the object, where it stands, and how it's rotated

    gl_Position = projectionMatrix * modelViewMatrix * vec4( position, 1.0 );
    gl_Position = projectionMatrix * viewMatrix * modelMatrix * vec4( position , 1.0 ); //will do the same thing
}

您使用三个材质制作的每种材质都具有着色器的这一部分。 例如，这还不足以进行照明，因为它没有法线。

试试这个片段着色器：

varying vec2 vUv; //coming in from the vertex shader

void main(){
    gl_FragColor = vec4( vUv , 0.0 , 1.0);
}

或更妙的是，让我们用颜色显示对象的世界位置：

顶点着色器：

varying vec3 vertexWorldPosition; 

void main(){

    vec4 worldPosition = modelMatrix * vec4( position , 1.0 ); //compute the world position, remember it, 
    //model matrix is mat4 that transforms the object from object space to world space, vec4( vec3 , 1.0 ) creates a point rather than a direction in "homogeneous coordinates"

    //since we only need this to be vec4 for transformations and working with mat4, we save the vec3 portion of it to the varying variable
    vertexWorldPosition = worldPosition.xyz; // we don't need .w

    //do the rest of the transformation - what is this world space seen from the camera's point of view,
    gl_Position = viewMatrix * worldPosition;

    //we used gl_Position to write the previous result, we could have used a new vec4 cameraSpace (or eyeSpace, or viewSpace) but we can also write to gl_Position

    gl_Position = projectionMatrix * gl_Position; //apply perspective distortion
}

片段着色器：

varying vec3 vertexWorldPosition; //this comes in from the vertex shader
void main(){
    gl_FragColor = vec4( vertexWorldPosition , 1.0 );
}

如果您在0,0,0处创建一个球体并且不移动它，则一半将为黑色，另一半将为彩色。 根据比例，它可能是白色的。 假设半径为100，您将看到一个从0到1的渐变，其余的将为白色（或r，g，b，固定为1.0）。 然后尝试这样的事情

 gl_FragColor = vec4( vec3( sin( vertexWorldPosition.x ) ), 1.0 );