运行时错误91; 将数据从Excel传输到Word表

Question

我目前为止发现的东西似乎很简单，现在遇到了麻烦。 我正在尝试通过VBA将数据从Excel工作簿链接到Word文档上的表格。 这是我到目前为止发现并稍有更改的代码...

Sub GetData()
    Dim strPath As String
    Dim strFileName As String
    Dim strFileExtension As String
    Dim strFullName As String

    strPath = "file path here"
    strFileName = "file name here"
    strFileExtension = "Extension here"
    strFullName = strPath & strFileName & strFileExtension

    Set objWorkbook = objExcel.Workbooks.Open(strFullName)

    'Set the text of the cell from Excel to the cell in the specified table in 
    'Word (the second table in this instance)   

    ActiveDocument.Tables(1).Cell(2, 2).Range.Text =  objWorkbook.Sheets("Sheet1") _
        .Cells(2, 1)

    'Close Excel bits
    objWorkbook.Close

    Set objWorkbook = Nothing
End Sub

我发现的最初错误是未在参考和简单语法错误中选中excel对象库。 修复这些问题后，我现在得到“运行时错误91对象变量或未设置块变量”。 当我尝试设置objWorkbook变量时，会发生此错误。 我已经声明了这些公共变量...

Public objExcel As Excel.Application
Public objWorkbook As Excel.Workbook
Public objWorksheet As Excel.Worksheet
Public objRange As Excel.Range

但是，当我查找此错误时，发现的全部是需要声明这些公共变量。 不知道从这里去哪里。 如果有人可以向正确的方向推动我，那将不胜感激。 另外，感谢您迄今为止提供的所有帮助，此网站可以挽救生命。

Answer 1

尝试这个：

Sub GetData()

  Dim strPath As String
  Dim strFileName As String
  Dim strFileExtension As String
  Dim strFullName As String

  dim objExcel As Object, objWorkbook As Object
  strPath = "file path here"
  strFileName = "file name here"
  strFileExtension = "Extension here"
  strFullName = strPath & strFileName & strFileExtension

  Set objExcel = CreateObject("Excel.Application")
  Set objWorkbook = objExcel.Workbooks.Open(strFullName)

  'Set the text of the cell from Excel to the cell in the specified table in 
  'Word (the second table in this instance)   

  ActiveDocument.Tables(1).Cell(2, 2).Range.Text =  objWorkbook.Sheets("Sheet1").Cells(2, 1)

  'Close Excel bits

  objWorkbook.Close
  objExcel.Quit
  Set objWorkbook = Nothing
  Set objExcel = Nothing



End Sub

顺便说一句，如果您使用上面使用的CreateObject函数，则不需要添加引用。

您遇到了两个问题：

1. 没有定义（设置） objExcel应用程序
2. 正确执行后没有关闭（清理）
3. Excel对象的不必要的公共声明