在R中使用Fortran子例程？ 未定义的符号

Question

这是我先前的问题的跟进。 我将Fortran代码包装在一个模块中，现在可以在运行时进行编译：

R CMD SHLIB ./Fortran/Fpi.f90

这是我的Fortran代码：

Module Fpi 
IMPLICIT NONE
contains 
    subroutine pi(avepi, DARTS, ROUNDS)
    double precision, intent(out)   ::  avepi
    integer, intent(in)             ::  DARTS, ROUNDS
    integer                         ::  MASTER, rank, i, n
    integer, allocatable            ::  seed(:)
    double precision                ::  pi_est, homepi, pirecv, pisum, dboard

    ! we set it to zero in the sequential run
    rank = 0
    ! initialize the random number generator
    ! we make sure the seed is different for each task
    call random_seed()
    call random_seed(size = n)
    allocate(seed(n))
    seed = 12 + rank*11
    call random_seed(put=seed(1:n))
    deallocate(seed)

    avepi = 0
    do i = 0, ROUNDS-1
      pi_est = dboard(DARTS)
      ! calculate the average value of pi over all iterations
      avepi = ((avepi*i) + pi_est)/(i + 1)
    end do
    end subroutine pi


    double precision function dboard(darts)
    integer, intent(in)           :: darts
    double precision              :: x_coord, y_coord
    integer                       :: score, n

    score = 0
    do n = 1, darts
      call random_number(x_coord)
      call random_number(y_coord)

      if ((x_coord**2 + y_coord**2) <= 1.0d0) then
      score = score + 1
      end if
    end do
    dboard = 4.0d0*score/darts

    end function


end module Fpi 

我正在尝试在R中运行此命令：

mypi <- function(DARTS, ROUNDS) {
  dyn.load("./Fortran/Fpi.so")
  retvals <- .Fortran("pi", DARTS = as.integer(DARTS) , ROUNDS = as.integer(ROUNDS), avepi = as.numeric(1))
  return(retvals$avepi)
}

mypi(DARTS = 50000, ROUNDS = 10)

我得到这个错误：

Error in dyn.load("./Fortran/Fpi.so") : 
  unable to load shared object '/home/ignacio/local/projects/PI/./Fortran/Fpi.so':
  /home/ignacio/local/projects/PI/./Fortran/Fpi.so: undefined symbol: dboard_

Answer 1

您的问题归结于dboard的声明：

   double precision                ::  pi_est, homepi, pirecv, pisum, dboard

在这里，您说的是dboard是外部函数，而不是模块过程。 这解释了为什么会有符号dboard_起作用。 您要删除它：

double precision                ::  pi_est, homepi, pirecv, pisum

而是在pi依赖dboard的模块过程性： pi在没有此声明的情况下已经知道它。

现在，除此之外，由于pi在模块中，因此该子例程本身将进行一些名称修饰。 我将使pi本身成为（C）可互操作的程序来解决此问题。

Module Fpi 
  IMPLICIT NONE
contains 
  subroutine pi(avepi, DARTS, ROUNDS) bind(C)
    use, intrinsic :: iso_c_binding, only : c_double, c_int
    real(c_double), intent(out)   ::  avepi
    integer(c_int), intent(in)    ::  DARTS, ROUNDS
    ...

然后使用.C而不是.Fortran 。

您可以将pi和dboard保留在模块中，而后者甚至不需要互操作。

Answer 2

尝试在R函数中固定fortran调用的名称。 您键入“ pi”，它应该是“ Fpi”。 另外，为什么不将函数带到您的路径而不是在函数内部传递长路径呢？

mypi <- function(DARTS, ROUNDS) {
  dyn.load("./Fortran/Fpi.so")
  retvals <- .Fortran("Fpi", DARTS = as.integer(DARTS) , ROUNDS = as.integer(ROUNDS), answer = as.numeric(1))
  return(retvals$answer)
}

mypi（DARTS = 50000，ROUNDS = 10）

Answer 3

显然，我无法将子例程包装在模块中。 此fortran代码有效：

subroutine dboard(darts, dartsscore)
  implicit none
  integer, intent(in)           :: darts
  double precision, intent(out) :: dartsscore
  double precision              :: x_coord, y_coord
  integer                       :: score, n

score = 0
do n = 1, darts
  call random_number(x_coord)
  call random_number(y_coord)

  if ((x_coord**2 + y_coord**2) <= 1.0d0) then
  score = score + 1
  end if
end do

dartsscore = 4.0d0*score/darts

end subroutine dboard

subroutine pi(avepi, DARTS, ROUNDS)
  implicit none
  double precision, intent(out)   ::  avepi
  integer, intent(in)             ::  DARTS, ROUNDS
  integer                         ::  MASTER, rank, i, n
  integer, allocatable            ::  seed(:)
  double precision                ::  pi_est, homepi, pirecv, pisum

interface 
   subroutine dboard(darts, dartsscore)
      implicit none
      integer, intent(in)           :: darts
      double precision, intent(out) :: dartsscore
   end subroutine dboard
end interface

! we set it to zero in the sequential run
rank = 0
! initialize the random number generator
! we make sure the seed is different for each task
call random_seed()
call random_seed(size = n)
allocate(seed(n))
seed = 12 + rank*11
call random_seed(put=seed(1:n))
deallocate(seed)

avepi = 0
do i = 0, ROUNDS-1
  call dboard(darts, pi_est)
  ! calculate the average value of pi over all iterations
  avepi = ((avepi*i) + pi_est)/(i + 1)
end do
end subroutine pi    

这是R代码：

system("R CMD SHLIB ./Fortran/Fpi.f90")

mypi <- function(DARTS, ROUNDS) {
  dyn.load("./Fortran/Fpi.so")
  retvals <- .Fortran("pi", avepi = as.numeric(1), DARTS =  as.integer(DARTS), ROUNDS =  as.integer(ROUNDS))
  return(retvals$avepi)
}

mypi(DARTS = 50000, ROUNDS = 10)