如何为递归单例类型定义NFData实例？

Question

我正在使用singletons库。 我有这种数据类型：

import Control.DeepSeq
import Data.Singletons.Prelude
import Data.Singletons.TH

data T =
      A
    | B [T]

genSingletons [''T]

我希望生成的单例类型ST是NFData实例。 如果类型T不是递归的，那将是直截了当的。 我试着写这个：

instance NFData (ST a) where
    rnf SA = ()
    rnf (SB (x `SCons` xs)) = rnf x `seq` rnf xs

但这在最后一行失败了：

Could not deduce (NFData (Sing n1)) arising from a use of `rnf'
from the context (a ~ 'B n)
  bound by a pattern with constructor
             SB :: forall (z_azEs :: T) (n_azEt :: [T]).
                   (z_azEs ~ 'B n_azEt) =>
                   Sing n_azEt -> Sing z_azEs,
           in an equation for `rnf'
or from (n ~ (n0 : n1))
  bound by a pattern with constructor
             SCons :: forall (a0 :: BOX) (z0 :: [a0]) (n0 :: a0) (n1 :: [a0]).
                      (z0 ~ (n0 : n1)) =>
                      Sing n0 -> Sing n1 -> Sing z0,
           in an equation for `rnf'
In the second argument of `seq', namely `rnf xs'
In the expression: rnf x `seq` rnf xs
In an equation for `rnf':
    rnf (SB (x `SCons` xs)) = rnf x `seq` rnf xs

我知道GHC希望模式SB (x ``SCons`` xs)) x和xs SB (x ``SCons`` xs))是NFData实例，但我无法弄清楚如何准确地告诉它。 我应该在这个实例的上下文中写什么才能使它工作？

Answer 1

首先，您需要为单例列表提供NFData实例。

instance NFData (SList '[]) where
  rnf SNil = ()

instance (NFData (Sing x), NFData (SList xs)) => NFData (SList (x ': xs)) where
  rnf (SCons x xs) = rnf x `seq` rnf xs

请注意，您无法在单个实例中解决此问题，因为这样您就无法提供递归的NFData约束：

instance NFData (SList xs) where
  rnf SNil = ()
  rnf (SCons x xs) = ? -- no way to know if NFData (Sing x)

同样，您必须为T案例编写单独的实例：

instance NFData (ST A) where
  rnf SA = ()

instance NFData (SList xs) => NFData (ST (B xs)) where
  rnf (SB xs) = rnf xs