在vb.net中将行转换为字符串

Question

有没有一种方法可以将行连接到VB代码而不是sql查询中的单个字符串中？

我有一个显示如下内容的查询：

+----------------+
| Col1 Col2 Col3 |
+----------------+
| 1    x    Joe  |
| 1    x    Sue  |
| 2    y    Sam  |
| 2    y    Mary |
+----------------+

我想要的是这样的：

1 x Joe, Sue
2 y Sam, Mary

Answer 1

您可以使用Join方法将数组转换为字符串。 这对于将单行转换为字符串通常很有用。 但是，您要的是选择性地将部分行组合为一个字符串。 可以做到这一点，但是您将不得不自己编写该方法。 如果您已经尝试过，请更新问题以包括您的代码。

Answer 2

这将完全按照您想要的方式执行，而且执行速度会更快

    Dim Dt As DataTable = New DataTable

    Dt.Columns.Add("Col1")
    Dt.Columns.Add("Col2")
    Dt.Columns.Add("Col3")

    Dt.Rows.Add("1", "x", "Joe")
    Dt.Rows.Add("1", "x", "Sue")
    Dt.Rows.Add("2", "y", "Sam")
    Dt.Rows.Add("2", "y", "Mary")

    Dim newRows = (From r As DataRow In Dt.AsEnumerable
                  Group By col1 = r("Col1"), col2 = r("Col2") Into newRow = Group
                  Select col1, col2, col3 = String.Join(", ", newRow.Select(Function(x) x("Col3")))).ToList

    For Each item In newRows
        Console.Write(item.col1.ToString & " " & item.col2.ToString & " " & item.col3.ToString)
    Next

Answer 3

是的，您使用的vb代码清晰易懂，可以通过查询na获取预期结果吗？

从这个问题还不清楚表名是什么，所以我将假设表名是sampleTable 。 现在，您可以使用以下查询来获取所需的详细信息。

select concat(col1,' ' ,col2,' ',group_concat(col3)) as result from sampletable group by col1;

Answer 4

@EJD有一个很好的工作解决方案。 这只是编码的一种变体：

Dt.AsEnumerable() _
    .GroupBy(Function(row) New With {Key .Group1 = row("Col1"), Key .Group2 = row("Col2")}) _
    .Select(Function(row) New With
            {.col1 = row.Key.Group1, .col2 = row.Key.Group2, .col3 = String.Join(", ", row.Select(Function(r) r("Col3")))}) _
    .ToList() _
    .ForEach(Sub(row) Console.WriteLine("{0} {1} {2}", row.col1, row.col2, row.col3))

这是另外两种Linq方法：

1. 采用Rows的财产DataTable
2. 使用DataTable的Select()方法

然后，我们根据第1列和第2列将这些行分组在一起。一旦分组在一起，就可以根据分组和String.Join()列3中的两个键创建新行。

代码示例：

Imports System
Imports System.Data
Imports System.Linq

Public Module Module1

    Public Sub Main()
        Dim Dt As DataTable = New DataTable
        Dt.Columns.Add("Col1")
        Dt.Columns.Add("Col2")
        Dt.Columns.Add("Col3")

        Dt.Rows.Add("1", "x", "Joe")
        Dt.Rows.Add("1", "x", "Sue")
        Dt.Rows.Add("2", "y", "Sam")
        Dt.Rows.Add("2", "y", "Mary")

        Dt.Rows.Cast(Of DataRow) _
            .GroupBy(Function(row) New With {Key .Group1 = row("Col1"), Key .Group2 = row("Col2")}) _
            .Select(Function(row) New With
                    {.col1 = row.Key.Group1, .col2 = row.Key.Group2, .col3 = String.Join(", ", row.Select(Function(r) r("Col3")))}) _
            .ToList() _
            .ForEach(Sub(row) Console.WriteLine("{0} {1} {2}", row.col1, row.col2, row.col3))

        Console.WriteLine()

        Dt.Select() _
            .GroupBy(Function(row) New With {Key .Group1 = row("Col1"), Key .Group2 = row("Col2")}) _
            .Select(Function(row) New With
                    {.col1 = row.Key.Group1, .col2 = row.Key.Group2, .col3 = String.Join(", ", row.Select(Function(r) r("Col3")))}) _
            .ToList() _
            .ForEach(Sub(row) Console.WriteLine("{0} {1} {2}", row.col1, row.col2, row.col3))
    End Sub
End Module

结果：

1 x Joe, Sue
2 y Sam, Mary

1 x Joe, Sue
2 y Sam, Mary