Perl：设置$ day，$ month和$ year

Question

我设法拼凑了一个脚本，该脚本可读取数千个日志条目并创建它们的摘要。 到目前为止一切都很好。 我还希望能够为它创建过去90天内条目的单独摘要。

日志中的单个条目如下所示，始终将新条目添加到文件底部：

序列号：10123407
日期：2015年8月14日
时间：12：58
循环类型：134 U
保持时间：0180
周期号：1357
干燥时间：00分钟。

循环开始
12：58.35

保持时间0000秒
周期：失败
User_Message 13
参考用户手册

循环结束
13：01.32

我用来返回当前日期和90天之前的日期的代码是：

use POSIX qw(strftime);  
use Time::Local qw(timegm);  
my ($d,$m,$y) = (localtime())[3,4,5];  
print OUT (strftime("%d/%m/%y - ", gmtime(timegm(0,0,0,$d,$m,$y)-90*24*60*60)));  
print OUT (strftime("%d/%m/%y\n", gmtime(timegm(0,0,0,$d,$m,$y))));

我这样做是因为它以我想要的格式生成日期，与日志dd / mm / yy中的格式相同，并且始终填充零。
使用此我得到以下输出：

15/11/15-09/08/15

因此，如果可以打印，如何将数据存储为变量： $day90 ， $month90 ， $year90 ， $day ， $month和$year 。 如果可以，那么我认为我可以做必要的逻辑操作，以确定日志条目是否在最近90天内，然后根据需要创建摘要。

我没有关于如何完成此操作的任何先入为主的想法，因此任何解决方案都将不胜感激。

Answer 1

比较日期的最佳方法之一是将它们转换为%Y%m%d格式（如果需要更易读的内容，则将其转换为%Y-%m-%d ），然后可以将它们作为文本字符串进行比较

您可以使用核心模块Time::Piece为您进行格式化

这是一个例子。 它将输入格式和比较格式分别定义为$dmy_format和$ymd_format

今天日期和90天之前的字符串已定义，并在首次调用in_range作为state变量存储，因此不再需要再次计算。 （您需要的Perl 5版本10或更好的state关键字。如果这是不可用，只是用my ，而不是和子程序之前 外 ，并立即移动这些定义）

传递的参数是DD/MM/YY格式的日期。 它被解析并重新格式化为YYYY-MM-DD并且该子例程返回将其与两个边界日期进行比较的结果

use strict;
use warnings;
use v5.10;   # for 'state' variables

use Time::Piece;
use Time::Seconds 'ONE_DAY';


for my $month ( 1 .. 12 ) {
  my $date = sprintf '14/%02d/15', $month;
  printf "date %s is %s\n", $date, in_range($date) ? 'in range' : 'out of range';
}


sub in_range {

    state $ymd_format = '%Y-%m-%d';
    state $dmy_format = '%d/%m/%y';

    state $now = localtime;
    state $today = $now->strftime($ymd_format);
    state $days90 = ($now - 90 * ONE_DAY)->strftime($ymd_format);

    my $date = Time::Piece->strptime(shift, $dmy_format)->strftime($ymd_format);

    $date le $today and $date ge $days90;
}

输出

date 14/01/15 is out of range
date 14/02/15 is out of range
date 14/03/15 is out of range
date 14/04/15 is out of range
date 14/05/15 is in range
date 14/06/15 is in range
date 14/07/15 is in range
date 14/08/15 is out of range
date 14/09/15 is out of range
date 14/10/15 is out of range
date 14/11/15 is out of range
date 14/12/15 is out of range

Answer 2

您可以使用它来获取日期到变量中，即用/分割并将其存储在变量中：

use strict;
use warnings;
use POSIX qw(strftime);  
use Time::Local qw(timegm);  
my ($d,$m,$y) = (localtime())[3,4,5];  
my ($day90,$month90,$year90) = split(/\//,(strftime("%d/%m/%y", gmtime(timegm(0,0,0,$d,$m,$y)-90*24*60*60))));
my ($day,$month,$year)=split(/\//,(strftime("%d/%m/%y", gmtime(timegm(0,0,0,$d,$m,$y)))));

print "DATE(BEFORE 90 days): $day90 $month90 $year90 \n";
print "DATE(CURRENT): $day $month $year \n";

输出：

DATE(BEFORE 90 days): 11 05 15 
DATE(CURRENT): 09 08 15