从下方遮罩AS3，保持遮罩可见？

Question

好的，我很确定这是不可能的，但是也许有人可以想到可以使这种情况发生的巧妙的组合效果：

我希望[大而复杂的]动画片段充当其上方另一个动画片段的遮罩，而不会消失。

关键是让用户将各种对象拖到角色上，并使它们“出现在皮肤上”，因此仅在角色动画片段所在的位置可见。 以前，我是通过创建与角色形状相同的蒙版来完成此操作的，但是这次角色MC非常复杂且动态，因此不可行。

有没有一种简单的方法可以动态复制复杂的MC并制作遮罩？ 有没有办法使用负空格而不是内容来使“擦除”过滤器擦除？ 有想法吗？

编辑：

起初，由于高像素化和缩放问题，下面的答案不起作用，但是我能够通过绘制父代来解决这些问题，允许按照建议进行平滑处理，并进行大量修补。

    // remove old bitmap to replace with new one as needed
    if(grl.tempContainer.numChildren >= 1){
        grl.tempContainer.removeChildAt(0);
    }
    // make hair disappear so only visible skin is part of mask
    grl.hair.cacheAsBitmap = true;
    grl.hair.blendMode = 'erase';
    grl.hair2.alpha = 0;
    grl.ponytail.alpha = 0;
    grl.body.braids.alpha = 0;
    grl.filters = [];
    grl.body.filters = [];

    // create bitmap copy of the character
    var bmd:BitmapData = new BitmapData(400, 600, true, 0);
    bmd.draw(this.parent);
    var clone:Bitmap = new Bitmap(bmd);
    clone.cacheAsBitmap = true;
    clone.smoothing = true;
    grl.tempContainer.addChild(clone);
    // undo the scaling effects that were on girl to revert to parent scaling/position
    clone.scaleX = 1/grl.scaleX;
    clone.scaleY = 1/grl.scaleY;
    clone.x = -(clone.width)/2;
    clone.y = -(75/(grl.scaleY));

    grl.draggieContainer5.cacheAsBitmap = true;
    grl.draggieContainer5.mask = clone;

    // reset character to look normal again
    grl.hair.blendMode = 'normal';
    grl.hair2.alpha = 1;
    grl.ponytail.alpha = 1;
    grl.body.braids.alpha = 1;
    grl.filters = filterHolder.filters;
    grl.body.filters = filterHolder.filters;

Answer 1

听起来您已经解决了这个问题，但是我认为您必须创建第二个字符对象以用于遮罩。

有没有一种简单的方法可以动态复制复杂的MC并制作遮罩？

如果您的mc是静态的，则可以先将其绘制为位图，然后将其用作遮罩。

import flash.display.Bitmap;

//Create Character
var character:Character = new Character();
character.x = 100;
character.y = 50;
stage.addChild(character);

//Clone it
var bmd:BitmapData = new BitmapData(character.width, character.height, false, 0);
bmd.draw(character);
var clone:Bitmap = new Bitmap(bmd);
clone.x = character.x;
clone.y = character.y;
stage.addChild(clone);

//Tattoo is masked to the clone
var tattoo:Tattoo = new Tattoo();
stage.addChild(tattoo);
tattoo.mask = clone;
stage.addEventListener(MouseEvent.MOUSE_MOVE, mousemove);
function mousemove(e:MouseEvent):void
{
    tattoo.x = mouseX;
    tattoo.y = mouseY;
}

编辑：

由于角色很可能具有透明区域，因此您实际上需要做更多的工作。 为了使位图透明，您需要将第三个参数设置为true，将第四个参数设置为0。

var bmd:BitmapData = new BitmapData(grl.body.width, grl.body.height, true, 0);

在您的角色体内，注册点位于中心，但是绘图功能从左上角开始绘制。 为了正确绘制，您需要将矩阵应用于绘制函数：

//Apply Matrix so the entire image gets drawn
var matrix:Matrix = new Matrix();
matrix.translate(grl.body.width/2, grl.body.height/2);
bmd.draw(grl.body, matrix);

//Draw the clone image
var clone:Bitmap = new Bitmap(bmd);

现在，您的位图应该可以正确显示，但是它的左上角应与原始图像的中心对齐。 您需要将其移回原来的位置。

var t:Transform = new Transform(clone);
matrix = new Matrix();
matrix.translate(grl.body.x-grl.body.width/2, grl.body.y-grl.body.height/2);
t.matrix = matrix;
clone.scaleX = grl.body.scaleX;
clone.scaleY = grl.body.scaleY;

现在您需要做2件事，以使遮罩正确地与Alpha通道融合。 您必须将显示对象和蒙版对象的混合模式设置为ALPHA，并且必须将cacheAsBitmap设置为true。

clone.cacheAsBitmap = true;
clone.blendMode = BlendMode.ALPHA;
grl.addChild(clone);

grl.draggieContainer.cacheAsBitmap = true;
grl.draggieContainer.mask = clone;