如何获得规则的RHS中的事实索引？

Question

我问是否有可能在defrule的RHS中访问获取事实索引？ 每次我尝试在RHS defrule中为事实建立索引时，它给我带来的不确定性。 因为我有一个while循环，所以我希望能够根据我的输入数据修改电梯事实。

(deftemplate elevator 
(slot goal))

(deffacts elevator
(elevator (goal 0))) 

(defrule read-data

=>
?f1 <- (elevator)
(modify ?f2 (goal 1))

)

这是我的代码示例，因为我无法全部上网：

(deftemplate data
(slot data)
)

(deffacts data
(data (data 1))
)

(defrule rule1
?f1 <-(data)
=>
(bind ?value (readline input) )
(while (neq ?value EOF) 
do
(bind ?data (fact-slot-value ?f1 data)) 
(printout t "data " ?data crlf )
(retract ?f1)
(modify ?f1 (data ?value))
(bind ?value (readline input) 
)

)
)

这是我的输入文件：

2
3
4
5
6
7

这就是我得到的：

CLIPS> (run)
data 1
data FALSE
data FALSE
data FALSE
data FALSE
data FALSE
CLIPS> 

我希望它打印出数据2数据3数据4 ..ect

Answer 1

您可以从规则的RHS中以这种方式执行此操作，但是，如果您的规则实际上没有LHS条件，则使用规则来更改事实的值是没有意义的。 只需使用一个功能。

CLIPS> 
(deftemplate elevator 
   (slot goal))
CLIPS> 
(deffacts elevator
   (elevator (goal 0))) 
CLIPS> 
(defrule read-data
   =>
   (do-for-fact ((?f elevator)) TRUE
      (modify ?f (goal 1))))
CLIPS> (watch facts)
CLIPS> (reset)
<== f-0     (initial-fact)
==> f-0     (initial-fact)
==> f-1     (elevator (goal 0))
CLIPS> (run)
<== f-1     (elevator (goal 0))
==> f-2     (elevator (goal 1))
CLIPS> 

或者，您可以在规则的条件下绑定要修改的事实：

CLIPS> (clear)
CLIPS> 
(deftemplate elevator 
   (slot goal))
CLIPS> 
(deffacts elevator
   (elevator (goal 0))) 
CLIPS> 
(defrule read-data
   ?f <- (elevator (goal 0))
   =>
   (modify ?f (goal 1)))
CLIPS> (watch facts)
CLIPS> (reset)
<== f-0     (initial-fact)
==> f-0     (initial-fact)
==> f-1     (elevator (goal 0))
CLIPS> (run)
<== f-1     (elevator (goal 0))
==> f-2     (elevator (goal 1))
CLIPS> 

更新：

通过删除撤回并将f1重新绑定到Modify返回的值，可以使原始规则“起作用”：

CLIPS> (clear)
CLIPS> 
(deftemplate data
   (slot data))
CLIPS> 
(deffacts data
   (data (data 1)))
CLIPS> 
(defrule rule1
   ?f1 <- (data)
   =>
   (bind ?value (readline input))
   (while (neq ?value EOF) 
      (bind ?data (fact-slot-value ?f1 data)) 
      (printout t "data " ?data crlf )
      (bind ?f1 (modify ?f1 (data ?value)))
      (bind ?value (readline input))))
CLIPS> (reset)
CLIPS> (open input.txt input)
TRUE
CLIPS> (run)
data 1
data 2
data 3
data 4
data 5
data 6
CLIPS> (close input)
TRUE
CLIPS>

在RHS上多次修改同一事实，仍然令人感到疑惑。