SPARQL和查询的[属性]

Question

我正在尝试在DBpedia中使用SPARQL从<http://dbpedia.org/ontology/Person>查询数据。 但是，我要匹配的属性被列为dbp:children of （示例在这里： http://dbpedia.org/page/Angelina_Jolie : http://dbpedia.org/page/Angelina_Jolie ）。

但是，在进行查询时， dbp:childrenOf ， dbo:children_of和其他类似的方法不起作用。 我应该如何要求该财产？

谢谢！

这是我的示例查询：

PREFIX   dbo:  <http://dbpedia.org/ontology/>
PREFIX  foaf:  <http://xmlns.com/foaf/0.1/>
PREFIX  rdfs:  <http://www.w3.org/2000/01/rdf-schema#>        
PREFIX  type:  <http://dbpedia.org/class/yago/>
PREFIX   dbp:  <http://dbpedia.org/property/> 

SELECT DISTINCT ?person ?birthDate ?birthPlace ?parents
WHERE {  
           ?person  a               dbo:Person .
         { ?person  rdfs:label      "Angelina Jolie"@en }
  UNION  { ?person  dbp:name        "Angelina Jolie"@en } .

           ?person  dbo:birthDate   ?birthDate.
           ?person  dbo:birthPlace  ?bp.
           ?bp      rdfs:label      ?birthPlace.
OPTIONAL { ?person  dbp:childrenOf  ?parents}
   FILTER (LANG(?birthPlace)='en')
}

我要修复的行是OPTIONAL子句。

Answer 1

不幸的是，我不认为安吉丽娜（Angelina）的任何孩子都拥有Wikipedia页面（因此没有DBpedia页面），因此您很难通过该特定示例来解决任何答案。

这是用于检索其他人的父母的查询的稍有不同的版本-

PREFIX dbo: <http://dbpedia.org/ontology/>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>        
PREFIX type: <http://dbpedia.org/class/yago/>
PREFIX dbp: <http://dbpedia.org/property/> 

SELECT DISTINCT ?person ?birthDate ?birthPlace ?parents
WHERE {  
      ?person a dbo:Person .

      {?person rdfs:label "Ras Barker"@en}
      UNION 
      {?person dbp:name "Ras Barker"@en}
      UNION 
      {?person dbo:birthName "Ras Barker"@en}

      OPTIONAL { ?person dbo:birthDate ?birthDate. }
      OPTIONAL { ?person dbo:birthPlace ?bp . ?bp rdfs:label ?birthPlace. }
      #OPTIONAL { ?person dbo:parent ?parents }
      OPTIONAL { ?parents dbo:child ?person }
      FILTER (LANG(?birthPlace)='en')
}

我选择使用dbo谓词child而不是childrenOf （不确定此谓词是否正在使用）。 将与出生相关的内容包装到OPTIONAL子句中，因为您不能100％依赖具有这些谓词的实例数据。