如何在mips中将字符串保存到数组中

Question

我对此代码有疑问。 我尝试通过输入输入字符串并将其保存到数组中，这是我的代码：

    .data
    .align 2
array:  .space 80
size: .word 20
string: .space 20
op: .asciiz "Enter the array length"
prompt: .asciiz "Enter a string:"
text:   .asciiz "The array of string is:"
newline: .asciiz "\n"
    .text
    .globl main

main:
    add $t0, $zero, $zero # index of array
    addi $t1, $zero, 1 # counter=1

    li $v0, 4
    la $a0, op
    syscall
    jal new_line

    li $v0, 5
    syscall

    addi $s0, $v0, 0 # $v0 contains integer read
read_string: 
    bgt $t1, $s0, L1 # if ($t1 > length)then go to L1

    li $v0, 4
    la $a0, prompt
    syscall

    la $a0, string
    li $a1, 20
    li $v0, 8
    syscall

    sw $a0, array($t0)
    addi $t0, $t0, 4
    addi $t1, $t1, 1

    j read_string

L1: #### here i want to print the array ####
    add $t0, $zero, $zero # index of array
    addi $t1, $zero, 1 # counter=1

    la $a0, text
    li $v0, 4
    syscall
    jal new_line

    while: bgt $t1, $s0, done
    lw $t2, array($t0)

    li $v0, 4
    move $a0, $t2
    syscall
    jal new_line

    addi $t0, $t0, 4
    addi $t1, $t1, 1
    j while

    new_line: la $a0, newline
    li $v0, 4
    syscall
    jr $ra

done: li $v0, 10
    syscall

麻烦的是该程序显示了我通过输入输入的最后一个字符串，例如

Enter the array length:
2
Enter a string:asd
Enter a string:123
The array of string is:
123

123

请我需要一些帮助，非常感谢，祝您有愉快的一天。

Answer 1

您的array索引逻辑似乎还可以，但是问题是您始终将每个条目存储为具有相同地址，即string的地址。 解决方案是更大的string区域，并在存储字符串时增加指向它的指针。

我已经纠正了您的代码[未测试]。 请原谅免费的样式清理，但是在尝试修复之前，我需要了解您的逻辑。 我添加了更多注释[我是一个老的asm伙计，并且我总是注释每一行]，并用[OLD]注释了您的代码，并用[NEW]注释了我的替换项。

    .data
    .align 2
array:      .space  80
size:       .word   20
###string:  .space  20          # [OLD]
string:     .space  20000       # [NEW]
op:         .asciiz "Enter the array length:"
prompt:     .asciiz "Enter a string:"
text:       .asciiz "The array of string is:"
newline:    .asciiz "\n"

    .text
    .globl main
main:
    # prompt user for array length
    li      $v0,4
    la      $a0,op
    syscall
    jal     new_line            # output newline

    # read in array count
    li      $v0,5
    syscall
    addi    $s0,$v0,0           # $v0 contains the integer we read

    add     $t0,$zero,$zero     # index of array
    addi    $t1,$zero,1         # counter=1
    la      $s2,string          # load address of string storage area [NEW]

read_string:
    bgt     $t1,$s0,L1          # if ($t1 > length) then array is done -- fly

    # prompt the user for next "string"
    li      $v0,4
    la      $a0,prompt
    syscall

    # get the string
### la      $a0,string          # place to store string [OLD]
    move    $a0,$s2             # place to store string [NEW]
    li      $a1,20
    li      $v0,8
    syscall

    # store pointer to string into array
    sw      $a0,array($t0)

    addi    $t0,$t0,4           # advance offset into pointer array
    addi    $t1,$t1,1           # advance iteration count
    addi    $s2,$s2,20          # advance to next string area [NEW]

    j       read_string

#### here i want to print the array ####
L1:
    add     $t0,$zero,$zero     # index of array
    addi    $t1,$zero,1         # counter = 1

    # output the title
    la      $a0,text
    li      $v0,4
    syscall
    jal     new_line

while:
    bgt     $t1,$s0,done        # more strings to output?  if no, fly
    lw      $t2,array($t0)      # get pointer to string

    # output the string
    li      $v0,4
    move    $a0,$t2
    syscall
    jal     new_line

    addi    $t0,$t0,4           # advance array index
    addi    $t1,$t1,1           # advance count
    j       while

# new_line -- output a newline char
new_line:
    la      $a0,newline
    li      $v0,4
    syscall
    jr      $ra

# program is done
done:
    li      $v0,10
    syscall

---

更新为了获得更多的荣誉，当您使用原始版本时，可以尝试用jal stradv替换addi $s2,$s2,20 jal stradv ，其中stradv是：

# stradv -- advance past end of string
stradv:
    ldb     $t2,0($s2)          # get char
    addi    $s2,$s2,1           # we pre-increment because we want EOS + 1
    bne     $t2,$zero,stradv    # is it EOS?  if no, loop some more
    jr      $ra

这将允许使用较大的可变长度字符串[如果您还增加了读取syscall的字符串的长度]。

这通常是我编写类似代码的方式，但是在基本代码完全起作用之前，我不想添加代码。