从列表中创建字典vb.net

Question

我有一个包含2列的列表（clm1 = StoreID和clmn2 = ProductID）。 我需要遍历此列表并创建一个字典（StoreID，List（of ProductID））我正在使用vb.net。 您能帮我做我要做的循环吗？ 列表数据类似于

StoreID  ProductID
1          234
2          456
1          222
3          768
1          100
9          876
e.t.c.

Answer 1

我假设您的数据存储如下：

Structure Item
    Public StoreID As Integer
    Public ProductID As Integer
End Structure

Dim l As List(Of Item)

然后，您有两个选择。 第一个是手工创建字典：

Dim dictionary As New Dictionary(Of Integer, List(Of Integer))
For Each item As Item In l
    Dim subList As List(Of Integer)
    Dim keyExists = dictionary.TryGetValue(item.StoreID, subList)
    If keyExists Then
        subList.Add(item.ProductID)
    Else
        subList = New List(Of Integer)
        subList.Add(item.ProductID)
        dictionary.Add(item.StoreID, subList)
    End If
Next

在这里，您只需迭代所有项目。 检查字典是否已经包含商店ID的条目。 如果是这样，只需添加产品ID。 如果不是，请创建一个条目，然后添加产品ID。

如果您不太关注性能，则可以使用以下LINQ表达式来创建字典：

Dim dictionary = l.GroupBy(Function(item) item.StoreID) _
                  .ToDictionary(Function(group) group.Key, _
                                Function(group) group.Select(Function(item) item.ProductID) _
                                                     .ToList())

首先，将元素按其StoreID分组。 然后， ToDictionary()方法创建字典。 它有两个参数。 第一个函数指定每个元素的键。 在这种情况下，我们要使用组的密钥作为字典密钥（这是商店ID）。 第二个参数是在字典中插入的值。 首先，我们使用Select将每个Item映射到其ProductID （因为我们要存储产品ID而不是整个项目。然后调用ToList()从组中的项目生成一个列表。