复制并粘贴到新工作表的最后一行

Question

我目前正在尝试使用VBA从一个工作表中复制并粘贴到新工作表中。 但是我有以下变量

• 带有要复制数据的工作表是动态的。 列保持不变，但行每周更改。
• 数据将添加到的新工作表是动态的。 列是相同的，但是新的工作表行每周增加（例如，第700行一个星期，下一个星期800行）。
• 被复制和粘贴的列（A和BC）是一致的。
• 数据应粘贴在新工作表的下一个可用行的A-BC列上

我目前设法提出了以下代码，但是我不断收到错误消息，并且不知道我在哪里出错，因为我是VBA的新手。

 Sub CandP()
'
'

Dim Last_Row As Long

Application.ScreenUpdating = False

Last_Row = Range("A2:BC2" & Rows.Count).End(xlUp).Row
Range("A2:BC2").Copy
Windows("Newsheet.xlsm").Activate
Range("$A2:BC$" & last_row).FillDown

End Sub

感谢所有帮助，谢谢

Answer 1

您可以尝试以下方法：

Option Explicit

    Sub CandP()

    Dim Last_Row1 As Long, Last_Row2 As Long
    Dim WB1 As Workbook, WB2 As Workbook
    Dim ws1 As Worksheet, ws2 As Worksheet

    Set WB1 = ThisWorkbook ' Workbook where you want to copy the data
    Set ws1 = WB1.Sheets("Sheet1") ' Change the name of your Sheet
    Set WB2 = Workbooks.Open("C:\Desktop\vba\Newsheet.xlsm") ' Enter the address of the Workbook you want to paste the data
    Set ws2 = WB2.Sheets("Sheet1") ' Change the name of your Sheet

    Last_Row1 = ws1.Range("A" & Rows.Count).End(xlUp).Row ' Determine the lastrow of the data to copy
    Last_Row2 = ws2.Range("A" & Rows.Count).End(xlUp).Row + 1 ' Determine the next empty row in order to paste the data

    ws1.Range("A2:BC" & Last_Row1).Copy ws2.Range("A" & Last_Row2)

    End Sub