在xsl：for-each之后获取标签值

Question

我有以下XML：

<Order>
  <jobDetails>
    <Question>
      <QuestionNumber>1</QuestionNumber>
      <QuestionResponse>
        <Response>Value</Response>
      </QuestionResponse>
    </Question>
    <Question>
      <QuestionNumber>2</QuestionNumber>
      <QuestionResponse>
        <Response>AnotherValue</Response>
      </QuestionResponse>
    </Question>
  </jobDetails>
</Order>

如果问题编号为2，我正在使用XSLT 1.0获取Response的值：我需要进一步查询它，并根据它输出不同的值。

我已经试过了：

<xsl:template match="Order">
  <xsl:for-each select="jobDetails/Question">
    <xsl:variable name="theSet" select="QuestionNumber[string(.)='2']" />
    <xsl:if test="$theSet">
      <xsl:when test="QuestionResponse/Response = 'Value'"><Response>SomeValue</Response></xsl:when> 
      <xsl:when test="QuestionResponse/Response = 'AnotherValue'"><Response>SomeOtherValue</Response></xsl:when>
    </xsl:if>
  </xsl:for-each>
</xsl:template>

...但是XSLT无法验证。

在此先感谢您的协助。

Answer 1

似乎您正在使它变得比所需的更加复杂。 如果您想测试对问题2的回答，则可以直接进行测试，而无需经历所有其他问题：

<xsl:template match="/Order">
    <xsl:variable name="resp2" select="jobDetails/Question[QuestionNumber='2']/QuestionResponse/Response" />
    <response>
        <xsl:choose>
            <xsl:when test="$resp2='Value'">SomeValue</xsl:when>
            <xsl:when test="$resp2='AnotherValue'">SomeOtherValue</xsl:when>
        </xsl:choose>
    </response>
</xsl:template>

请注意，这假设整个XML中仅存在一个问题2（您尚未回答关于此的问题）。 否则，我们将需要说明如何输出多个结果。

Answer 2

我希望这对您有帮助：

编辑：我为此添加了更多解决方案：

<xsl:template match="/jobDetails">
  <Output>
    <Best>
      <xsl:choose>
        <xsl:when test="Question[QuestionNumber = '2']/QuestionResponse[Response = 'AnotherValue']">
          <Response>This is for you</Response>
        </xsl:when>
      </xsl:choose>
    </Best>
    <Looping>
      <xsl:for-each select="./Question">
        <Var>
          <!-- This is the original statement from you! Watch the output of it! -->
          <xsl:value-of select="QuestionNumber[string(.)='2']"/>
        </Var>
        <!-- Using the choose statement! -->
        <xsl:choose>
          <!-- You should list the ones you want to output -->
          <xsl:when test="QuestionNumber = 1">
            <Response>Just Some Value</Response>
          </xsl:when>
          <xsl:when test="QuestionNumber = 2">
            <Response>We found an interesting QuestionNumber</Response>
          </xsl:when>
          <xsl:otherwise>
            <Response>More Value</Response>
          </xsl:otherwise>
        </xsl:choose>

        <ApplyTemplate>
          <!-- We can use template for this too-->
          <xsl:apply-templates select ="."/>
        </ApplyTemplate>

      </xsl:for-each>
    </Looping>
  </Output>
</xsl:template>

<xsl:template match="Question[QuestionNumber = 2]">
  <ProcessTemplate>
    <!-- This is also perfect if you want to do more staff here-->
    <xsl:choose>
      <!-- You should list the ones you want to output -->
      <xsl:when test="QuestionResponse/Response = 'AnotherValue'">
        <Response>This is for you too</Response>
      </xsl:when>
      <xsl:when test="QuestionResponse/Response = 'SomeValue'">
        <Response>You wont graduate</Response>
      </xsl:when>
    </xsl:choose>
  </ProcessTemplate>
</xsl:template>

<xsl:template match="Question">
  <!-- This is empty for the case we did not match -->
  <Response>We don't have rule for this</Response>
</xsl:template>

这将输出以下xml：

<Output>
  <Best>
    <Response>This is for you</Response>
  </Best>
  <Looping>
    <Var></Var>
    <Response>Just Some Value</Response>
    <ApplyTemplate>
      <Response>We don't have rule for this</Response>
    </ApplyTemplate>
    <Var>2</Var>
    <Response>We found an intresting QuestionNumber</Response>
    <ApplyTemplate>
      <ProcessTemplate>
        <Response>This is for you too</Response>
      </ProcessTemplate>
    </ApplyTemplate>
  </Looping>
</Output>