如何将Excel文件保存在Win32 :: OLE的工作目录中

Question

我正在尝试在perl中解析Excel文件。 从中提取所需的信息后，我关闭Excel文件。 最后，我尝试将一个具有不同名称的新Excel文件保存在同一目录中。 但是此Excel已存储在“我的文档”文件夹中。

use Storable ;
use Cwd;

use Win32::OLE ;
use Win32::OLE qw(in with) ;
use Win32::OLE in ;
use Win32::OLE::Const 'Microsoft Excel';

use Excel::Writer::XLSX;

my $Excel = Win32::OLE->new("Excel.Application");
my $excel = $Excel->Workbooks->Add();

my $sheet = $excel->Worksheets(1);
$sheet->Activate();

my $new_file = "Temp_file.xlsm";
my $new_excel = cwd.'\\'.$new_file;
$new_excel =~ s/\//\\/g;

$excel->SaveAs($new_excel);

$Excel->{DisplayAlerts} = 0;
$excel->{Saved} = 1;
$excel->Close;

Answer 1

这是根据您的代码进行的更新。 首先，您要让Win32::OLE错误被静默忽略。 而是设置： $Win32::OLE::Warn = 3以便每当出现问题时它就会嘎吱作响。 其次，您尝试获取Excel.Application实例的方式不正确。 一方面，如果出现问题，您将拥有Excel实例，这些实例将保持浮动。

您还将混淆一个Excel实例，一个工作簿及其包含的图纸。 如果确实有$Win32::OLE::Warn = 3 ，那么您将收到有关发生问题的位置的通知。

您还应该在脚本中始终use strict并use warnings 。 如果其他人知道您的问题不是由一些琐碎的错字引起的，他们将更倾向于尝试提供帮助。

您也不需要三个单独的use Win32::OLE语句。

“作品”下面的代码。 与您的比较。

最后，如果要通过Win32::OLE处理工作表，则没有理由在代码中包含Excel::Writer::XLSX 。

use feature 'say';
use strict;
use warnings;

use File::Spec::Functions qw( rel2abs );
use Win32::OLE qw(in with) ;
use Win32::OLE::Const 'Microsoft Excel';
$Win32::OLE::Warn = 3;

my $excel = eval {
        Win32::OLE->GetActiveObject('Excel.Application');
    } || Win32::OLE->new('Excel.Application', sub { $_[0]->Quit });

my $wb = $excel->Workbooks->Add;
my $sheet = $wb->Worksheets->Add;

$wb->SaveAs( rel2abs('temp_file.xlsm') );

$excel->{DisplayAlerts} = 0;
$wb->{Saved} = 1;
$wb->Close;