在SAS中，找到组中所有其他观察值的平均值

Question

我试图找到同一组中所有其他观察值的平均值 。

我的数据就像

Value        Name    Group   Mean_all_other
544          Pete      1        ....
997          Sara      1        ....
772          Tom       1        ....
725          Tris      2        ....
872          Lulu      2        ....
434          Mica      2        ....
728          Tina      2        ....
827          Bo        3        ....
322          Zu        3        ....
.....        ...     ...         ...

我知道proc means可以给您群体内的平均值。 但是在这里，我想创建同一组中所有其他值的平均值 。

在这种情况下，Meet_all_other下的Pete将显示884.5，等于（997 + 772）/ 2。

萨拉=（544 + 772）/ 2 = 658; 三=（872 + 434 + 728）/ 3 = 678

有人有什么主意吗？

Answer 1

考虑一个proc sql解决方案，该解决方案使用子查询为每行平均相同的Group并调整当前Name 。 下面的查询使用SAS的不等于运算符^=和mean()函数，它们在常规SQL中将使用<>运算符和avg() -两者均仍符合SAS​​）。

proc sql;
    create table NewTable as
      select * from
      (select main.Value, main.Name, main.Group,
            (select mean(sub.Value) 
             from CurrentTable sub
             where sub.Group = main.Group
             and sub.Name ^= main.Name) As Mean_all_other
       from CurrentTable as main)

quit;

* Value Name    Group   Mean_all_other
* 544   Pete    1       884.5
* 997   Sara    1       658
* 772   Tom     1       770.5
* 725   Tris    2       678
* 872   Lulu    2       629
* 434   Mica    2       775
* 728   Tina    2       677
* 827   Bo      3       322
* 322   Zu      3       827

Answer 2

一旦获得了整个组的均值，就可以更轻松地计算出每个观察值的个案删除均值。 我建议通过双DOW循环进行此操作：

data have;
input Value  Name $   Group;
cards;
544          Pete      1
997          Sara      1
772          Tom       1
725          Tris      2
872          Lulu      2
434          Mica      2
728          Tina      2
827          Bo        3
322          Zu        3
;
run;

data want;
    do _N_ = 1 by 1 until(last.group);
        set have;
        by group;
        value_sum = sum(value_sum,value);
        value_count = sum(value_count,1);
    end;
    do _N_ = 1 to _N_;
        set have;
        mean_all_other = (value_sum - value)/(value_count - 1);
        output;
    end;
    drop value_:;
run; 

Answer 3

PROC SQL会很高兴为您重新合并摘要统计信息。 请注意，此语法可能无法在其他SQL实现中使用，但在SAS中可以正常使用。 您可以使用DIVIDE函数避免只有一个成员的组被零除。

create table want as
  select *
       , divide(sum(value) - value, n(value) - 1) as mean_all_other
  from have
  group by group
;

对于其他SQL实现，您将需要自己重新合并汇总结果。

create table want as
  select a.*
       , divide(b.sum_value - a.value, b.n_value - 1) as mean_all_other
  from have a
     , (select group,sum(value) as sum_value,n(value) as n_value
        from have
        group by group
       ) b
  where a.group = b.group
;

如果可能缺少VALUE的值，则需要添加CASE语句来处理这些情况。

create table want as
  select *
       , case when (missing(value)) then mean(value)
              else divide(sum(value) - value, n(value) - 1)
         end as mean_all_other
  from have
  group by group
;