Antlr4语法问题（不完全解析）

Question

我是ANTLR的新手，正在尝试使此语法有效：

grammar TemplateGrammar;

//Parser Rules 

start
    : block
    | statement
    | expression
    | parExpression
    | primary
    ;

block
    : LBRACE statement* RBRACE
    ;

statement
    : block
    | IF parExpression statement (ELSE statement)?
    | expression
    ;

parExpression
    : LPAREN expression RPAREN
    ;

expression
    : primary #PRIMARY
    | number op=('*'|'/') number            #MULDIV
    | number op=('+'|'-') number            #ADDSUB
    | number op=('>='|'<='|'>'|'<') number  #GRLWOREQUALS
    | expression op=('='|'!=') expression   #EQDIFF
    ;

primary
    :   parExpression
    |   literal
    ;

literal
    :   number  #NumberLiteral
    |   string  #StringLiteral
    |   columnName #ColumnNameLiteral
    ;

number
    :   DecimalIntegerLiteral       #DecimalIntegerLiteral
    |   DecimalFloatingPointLiteral #FloatLiteral
    ;

string
    :   '"' StringChars? '"'
    ;

columnName
    :   '[' StringChars? ']'
    ;

// Lexer Rules

//Integers
 DecimalIntegerLiteral
    :   DecimalNumeral
    ;

 fragment
 DecimalNumeral
    :   '0'
    |   NonZeroDigit (Digits? | Underscores Digits)
    ;

 fragment
 Digits
    :   Digit (DigitOrUnderscore* Digit)?
    ;

 fragment
 Digit
    :   '0'
    |   NonZeroDigit
    ;

 fragment
 NonZeroDigit
    :   [1-9]
    ;

 fragment
 DigitOrUnderscore
    :   Digit
    |   '_'
    ;

 fragment
 Underscores
    :   '_'+
    ;

//Floating point
DecimalFloatingPointLiteral
    :   Digits '.' Digits? ExponentPart?
    |   '.' Digits ExponentPart?
    |   Digits ExponentPart
    |   Digits
    ;

fragment
ExponentPart
    :   ExponentIndicator SignedInteger
    ;

fragment
ExponentIndicator
    :   [eE]
    ;

fragment
SignedInteger
    :   Sign? Digits
    ;

fragment
Sign
    :   [+-]
    ;

//Strings

StringChars
    :   StringChar+
    ;

fragment
StringChar
    :   ~["\\]
    |   EscapeSequence
    ;

fragment
EscapeSequence
    :   '\\' [btnfr"'\\]
    ;

//Separators
LPAREN          : '(';
RPAREN          : ')';
LBRACE          : '{';
RBRACE          : '}';
LBRACK          : '[';
RBRACK          : ']';
COMMA           : ',';
DOT             : '.';

//Keywords
IF              : 'IF';
ELSE            : 'ELSE';
THEN            : 'THEN';

//Operators
PLUS            : '+';
MINUS           : '-';
MULTIPLY        : '*';
DIVIDE          : '/';
EQUALS          : '=';
DIFFERENT       : '!=';
GRTHAN          : '>';
GROREQUALS      : '>=';
LWTHAN          : '<';
LWOREQUALS      : '<=';
AND             : '&';
OR              : '|';

WHITESPACE : ( '\t' | ' ' | '\r' | '\n'| '\u000C' )+ -> skip ;

当我在输入中输入"Test"时，它正在工作并返回字符串"Test" 。

这是我在输入中输入"Test"时在IParseTree得到的IParseTree ：

“（开始（声明（表达式（主要（文字（字符串\\“测试\\”）））））））”

但是，当我放入[Test] （与"Test"几乎一样，但用大括号而不是引号）时，解析器无法识别标记...

这是我放[Tree]时得到的IParseTree ：

“（开始[测试]）”

同样的，数字，它也承认孤独的数字，如1 ， 123 ， 12.5 ，等等，但没有这样的表达式1+2 ...

您是否知道解析器为什么不识别columnNames规则，但与string规则配合使用呢？

Answer 1

可能是因为您的目的定义了不正确的“ StringChar”？ 它不处理“]”

也许您想将StringChar定义为：

fragment
StringChar
:   ~["\\\]]
|   EscapeSequence
;

如果这是我的语法，我将为引用的字符串定义一个QuotedStringChar，并将BracketStringChar定义为〜[\\] \\\\]以用于您的括号列名称。

欢迎您在词汇层调试语法，并为不同类型的字符串定义不同类型的“引号”。 这很普遍。 （您应该看到Ruby，您可以在其中以字符串开头ick定义字符串引号。）

Answer 2

我最终通过以下方法使它起作用：

QuotedStringChars
    :   '"' ~[\"]+ '"'
    ;

BracketStringChars
    :   '[' ~[\]]+ ']'
    ;

在引号或方括号之间使用任何字符。 然后 ：

primary
    :   literal #PrimLiteral
    |   number  #PrimNumber
    ;

literal
    :   QuotedStringChars   #OneString
    |   BracketStringChars  #ColumnName
    |   number              #NUMBER
    ;

number
    :   DecimalIntegerLiteral       #DecimalIntegerLiteral
    |   DecimalFloatingPointLiteral #FloatLiteral
    ;

literal规则有助于区分带引号的字符串，方括号和数字。

在primary规则和literal规则中number是重复的，因为我需要为每个应用程序使用不同的行为。

我用Ira Baxter的好建议来解决这个问题：)

希望这可以帮助其他像我这样的ANTLR新手获得更好的理解:)