Gnuplot-标签切除图

Question

我的x和y标签被剪掉了

我找到了“裁剪/未修剪”选项，但是没有用。 如何设置保证金？ 如您所见，标题（右上方）被数据覆盖。 我如何在那里设置边距？

以下代码来自我的bash脚本。

#set output
 set terminal png large size 1920,1080 enhance background rgb '$BKGD_COLOR' 
 set output '$PLOT_OUTPUT_DIR/BW_${ArrayFile[$j]}_$DATE.png'

 #set data
 set datafile separator ","
 set timefmt '%d/%m/%Y %H:%M:%S'
 set xdata time
 set format x "%d/%m/%Y\n%H:%M:%S"

 #set axis (new style named 11, disable top and right axis, disable tics on top and right)
 set style line 11 linecolor rgb '$TEXT_COLOR' linetype 1
 set border 3 back linestyle 11
 set tics nomirror font "/usr/share/fonts/dejavu/DejaVuSans-Bold.ttf,16" textcolor rgb "$TEXT_COLOR" 

 #set grid
 set style line 12 linecolor rgb '$TEXT_COLOR' linetype 0 linewidth 1
 set grid back ls 12

 #set line style
 set style line 1 lc rgb '$RCVD_COLOR' pt 1 ps 1 lt 1 lw 2 
 set style line 2 lc rgb '$SENT_COLOR' pt 6 ps 1 lt 1 lw 2 

 #set text
 set key font "/usr/share/fonts/dejavu/DejaVuSans-Bold.ttf,10" textcolor rgb "$TEXT_COLOR"          
 set title 'Bandwidth (Mbps)' font "/usr/share/fonts/dejavu/DejaVuSans-Bold.ttf,14" textcolor rgb '$TEXT_COLOR'
 #Removed - set ylabel 'Mbps' textcolor rgb '$TEXT_COLOR'
 set yrange [0:*]

#plot using the column 1 and 3 of the CSV file. with line points and title 'Bytes Received' and line style 1 (as defined above)
plot '$DIR/ResultsCSV/mg_bandwidth/${ArrayFile[$j]}.csv' u 1:3 w lp ls 1 t 'Bytes Received', '$DIR/ResultsCSV/mg_bandwidth/${ArrayFile[$j]}.csv' u 1:4 w lp ls 2 t 'Bytes Sent'  

Answer 1

设置终端时，设置tic的字体大小。 此大小用于确定自动边距：

set terminal png ... font ',16'

另外，您可以使用

set lmargin screen 0.05
set bmargin ...

有关可能的坐标类型，请参见例如https://stackoverflow.com/a/23180595/2604213

顺便说一句：使用具有更好渲染质量的pngcairo终端。

Answer 2

@Christoph提供了有关保证金的答案，但您也询问了密钥。

为了解决这个问题，您可以将钥匙放在其他位置。 干

set key inside top left

会将密钥移到左侧，数据将不会被覆盖。 您也可以将其完全移动到情节之外

set key outside top right

会将其移动到图的右侧和外部（不会被掩盖）。

有关更多详细信息，请参见help set key 。