使用 SAS 中的另一个表更新一个表

Question

我有表 t1 和 t2，如何创建表 t3？ 基本上我想更新 t1 中的 Var2，其中 t1.Key=t2.Key，使用来自 t2 的数据，同时保持 t1 中的其他所有内容相同。

表 t1

Key Var1 Var2

1    A    AA
2    B    BB
3    C    CC
4    D    DD
5    E    EE

表 t2

Key Var1 Var2
3    C    XX
4    D    YY
6    F    FF

表 t3

Key Var1 Var2
1    A    AA
2    B    BB
3    C    XX
4    D    YY
5    E    EE

以下 SAS 代码只会给我错误：

proc sql;
update t1 
set  var2 = t2.var2
from t1
inner join t2 on 
t1.key=t2.key;
quit;

谢谢！

Answer 1

可以这样做：

data t1;
  input Key Var1 $ Var2 $;
  datalines;
1    A    AA
2    B    BB
3    C    CC
4    D    DD
5    E    EE
;

data t2;
  input Key Var1 $ Var2 $;
  datalines;
3    C    XX
4    D    YY
6    F    FF
;

title 'Table T1';
proc print data=t1 noobs;run;

title 'Table T2';
proc print data=t2 noobs;run;

更新本身：

proc sql;
  update t1 set var2 = (select var2 from t2 where t2.key=t1.key)
    where t1.key in(select key from t2);
quit;

查看：

title 'Updated T1';
proc print data=t1 noobs;run;

Answer 2

您可以在数据步骤中使用update语句。 Update语句与merge语句非常相似，不同之处在于除非您指定，否则它们不会用缺失值替换填充值。 此外，非唯一键会生成警告，这有助于调试。

更新表和同时创建新表的一般语法：

句法

data NewTable;
    update MasterTable
           TransactionTable;
    by key(s);
run;

为了对您的数据进行update操作，您需要确保您的两个数据集按关键变量排序或索引。 如果它没有排序或索引，SAS 会抱怨并且更新将失败。 通常，我只在创建主数据集或事务数据集所需的最后步骤中添加index选项。 由于避免了额外的排序步骤，因此可以节省一些时间。

第 1 步：确保表 1 和 2 被索引或按关键字排序

data t1(index=(key) );
    <ETL stuff>;
run;

data t2(index=(key) );
    <ETL stuff>;
run;

步骤 2：通过使用 t2 中的匹配值更新 t1，创建一个新表 t3

data t3(index=(key) );
   update t1(in=t1_key)  /* Same thing as SQL t1.key */
          t2(in=t2_key); /* Same thing as SQL t2.key */
   by key;

   /* This is SAS's way of specifying a left-join */
   if(t1_key);
run;

虽然您在此处并不特别需要t3上的index=选项，但保持您的关键变量索引或对其应用完整性约束是一种很好的做法。