如何在Oracle 10g中使用成员

Question

我想检查一个元素是否是sys.odcinumberlist varray的成员。

但这不起作用...

我的代码有什么问题？

DECLARE
  v_list sys.Odcinumberlist := sys.Odcinumberlist( 1, 2, 3, 4 );
BEGIN

  FOR i IN 1..v_list.COUNT LOOP
    dbms_output.put_line( v_list(i) );
  END LOOP;

  IF 1 MEMBER OF v_list THEN
    dbms_output.put_line( 'yes' );
  ELSE
    dbms_output.put_line( 'no' );    
  END IF;

END;

该代码引发的错误是

ORA-06550: line 9, column 6:
PLS-00306: wrong number or types of arguments in call to 'MEMBER OF'
ORA-06550: line 9, column 3:
PL/SQL: Statement ignored

Answer 1

SYS.Odcinumberlist为VARRAY，VARRAYS不支持嵌套表的比较。 此处更多信息-> https://docs.oracle.com/cd/B12037_01/appdev.101/b10799/adobjcol.htm
您可以为此使用SQL和表函数。 参见下面的例子

DECLARE
  v_list sys.Odcinumberlist := sys.Odcinumberlist( 1, 2, 3, 4 );
  v_member_found char(3);
BEGIN

  FOR i IN 1..v_list.COUNT LOOP
    dbms_output.put_line( v_list(i) );
  END LOOP;

  begin
   select 'yes' into v_member_found 
    from table(v_list) 
   where column_value = 1;
  exception
    when no_data_found 
     then v_member_found := 'no';
  end;
  dbms_output.put_line(v_member_found);

END;

或者，您可以遍历集合

DECLARE
  v_list sys.Odcinumberlist := sys.Odcinumberlist( 1, 2, 3, 4 );
  v_member_found boolean := false;
BEGIN

  FOR i IN 1..v_list.COUNT LOOP
    dbms_output.put_line( v_list(i) );
  END LOOP;


  For i in 1..v_list.COUNT LOOP <<SearchLoop>>
    if v_list(i) = 1 then
       dbms_output.put_line('Member exists');
       v_member_found:=true;
       exit;
    end if;
  end Loop SearchLoop;

  if not v_member_found then
    dbms_output.put_line('member does not exist'); 
  end if;

END;

Answer 2

由于SYS.Odcinumberlist是VARRAY，因此不支持比较。 您可以按照以下说明使用嵌套表类型。

SET SERVEROUTPUT ON;
DECLARE
TYPE v_list_tab
IS
  TABLE OF NUMBER;
  v_list v_list_tab:=v_list_tab(1,2,3,4,5);
BEGIN
  FOR i IN 1..v_list.COUNT
  LOOP
    dbms_output.put_line( v_list(i) );
  END LOOP;
  IF 1 MEMBER OF v_list THEN
    dbms_output.put_line( 'yes' );
  ELSE
    dbms_output.put_line( 'no' );
  END IF;
END;