Ubuntu，Bash，awk，正则表达式->在文本文件中找到所有[数字]并打印

Question

我想在“ []”括号中找到每个数字，并在文本文件中打印其所有外观（行号）。

例如，我得到了这样的文本文件：

texttexttext[1] textetxtetete[2]
[1]textextetetete[3]
texttexttext[2]
texttexttext
text[3]text[1]

输出应该是这样的：

[1] = lines : 1 2 5
[2] = lines : 1 3
[3] = lines : 2 5

到目前为止，这是我所做的：

#!/bin/bash
cat $1 | awk -F'[/[/] ]' '{     #[] as file separators
for (i=1;i<=NF;i++)             #for every part of line
  {
  if ($i ~ "[0-9]+")            #if its number
    {
      #save it somehow
    }
}}'

该脚本找到了所需的数字，但是现在我想以某种简单的方式保存它及其行号（NR变量）。 我应该尝试使用数组吗？ 我至少需要二维数组，但是在bash中它们有点问题。 有什么更好的方法吗？

Answer 1

这是使用awk（和一维数组）的解决方案

awk -F"[\],\[]" '{
for (i=1;i<=NF;i++)
  {
  if ($i ~ "[0-9]+")
    {
      arr[$i]=arr[$i]" "NR
    }
   }
} 
END{for(i in arr){print "["i"] lines : " arr[i]}}' t.txt

输出：

[1] lines :  1 2 5
[2] lines :  1 3
[3] lines :  2 5

备注：regex [0-9]+也匹配包含字符（例如4a ）的字符串。 如果您的输入文件包含[45a]并且要排除此内容，则将正则表达式更改为^[0-9]+$ 。

Answer 2

这是使用gawk的FPAT和sorted_in的变体：

    BEGIN { # define fields via FPAT and sort order 
        FPAT="\[[0-9]+\]" 
        PROCINFO["sorted_in"] = "@ind_str_asc"
        }
    { for (i = 1; i <= NF; i++) occ[ $i ] = occ[ $i ] " " FNR }

    END { for( i in occ ) printf( "%s = lines : %s\n", i, occ[ i ] ) }