对Haskell的前n个奇数求和

Question

我是Haskell的新手，而且还是功能编程的新手，我想知道您将如何在Haskell中编写这样的函数。 我已经习惯了命令式语言，但是现在在haskell中处理递归对我来说是遥不可及的。 注意，我知道奇数之和可以用n ^ 2来完成（即3个第一个奇数1 + 3 + 5 = 9 = 3 ^ 2的总和），但是其思想是通过函数式编程学习递归。

另外，我正在做这是代数研讨会的一部分，我们还没有看到太多。 我需要一种仅通过递归来解决的方法。

有什么提示吗？ 谢谢！

Answer 1

-- the odd numbers (all of them!)
[ 1,3.. ]

-- the first N odd numbers:
take n [1,3..]

-- the sum of the first N odd numbers
sum (take n [1,3..])

把它放在一个函数中：

sumOddNumbers n = sum (take n [1,3..])

Answer 2

首先，您需要描述您的功能。

sumFirstOdds :: Int -> Int

当您考虑递归时，您将需要一个停止点。 在这种情况下，良好的停止点是前零个奇数之和，即零。 您可以这样定义基本情况：

sumFirstOdds 0 = 0

编写递归函数时，养成先声明停止点的习惯是很好的。 否则，您很容易陷入无限循环。

现在我们需要定义当n > 0时要查找前n奇数之和时会发生什么。

首先，您需要找到一种方法来获取第n个奇数的值： (n * 2) - 1 。

现在为递归部分。 通过列举一些简单的示例，可以帮助您考虑问题。 如果我们想获得前三个奇数的和，则可以使用如下公式：

((3 * 2) - 1) + ((2 * 2) - 1) + ((1 * 2) - 1) + 0
  ^               ^               ^             ^
  |               |               |             |
n == 3          n == 2          n == 1        n == 0 (base case)

从请求的3开始使用相同的算法，然后将其添加到针对2运行的相同算法的结果中，然后对1执行相同的操作，然后对0执行相同的操作，这是我们遇到的基本情况并停止。

放入Haskell代码中，您可以将其写为：

sumFirstOdds n = ((n * 2) - 1) + (sumFirstOdds (n-1))

针对当前n值执行计算，并将该值添加到针对该n-1值使用的同一函数的结果中。

要重申最终功能的样子，是这样的：

sumFirstOdds :: Int -> Int
sumFirstOdds 0 = 0
sumFirstOdds n = ((n * 2) - 1) + (sumFirstOdds (n-1))

注意：这不能很好地处理负输入，但是为了简单起见，我省略了它

Answer 3

既然你应该总是通过总结平方的单号，我认为这将是有趣通过递归做到这一点 。 由于对于Int或Integer这样做是很愚蠢的，因此您应该在类型级别上工作。 这实际上就像将它们幼稚的方式加起来一样慢，但是它更有趣！

{-# LANGUAGE DataKinds, KindSignatures, TypeFamilies, TypeOperators, GADTs, UndecidableInstances #-}

data Nat = Z | S Nat

infixr 6 :+
type family (:+) (x :: Nat) (y :: Nat) :: Nat where
  'Z :+ n = n
  'S m :+ n = 'S (m :+ n)

infixr 7 :*
type family (:*) (x :: Nat) (y :: Nat) :: Nat where
  'Z :* n = 'Z
  'S m :* n = n :+ m :* n

现在，要使其可用，您可以将其降低到单身人士的学期水平。

data Natty :: Nat -> * where
  Zy :: Natty 'Z
  Sy :: Natty n -> Natty ('S n)

plus :: Natty m -> Natty n -> Natty (m :+ n)
plus Zy n = n
plus (Sy m) n = Sy (plus m n)

times :: Natty m -> Natty n -> Natty (m :* n)
times Zy _ = Zy
times (Sy m) n = n `plus` (m `times` n)

square :: Natty n -> Natty (n :* n)
square n = times n n

Answer 4

在这里不需要它，但是通常您可以在辅助函数中使用累加器进行递归计算。

sumodds n = go n 0
   where go 0 a = a
         go k a = go (k-1) (a + 2*k-1)

> map sumodds [0..9]
[0,1,4,9,16,25,36,49,64,81]