如何搜索和替换里面有等号“=”的字符串

Question

我必须从像 Pippo.K=5 这样的 txt 中搜索一个字符串并将其替换为 Pippo.K=1。 我需要搜索整个字符串。 我所做的是：

set "search=Pippo.K=5"
set "replace=Pippo.K=1"
set "textFile=%SettingFile%.txt"
for /f "delims=" %%i in ('type "%textFile%" ^& break ^> "%textFile%" ') do (
    set "line=%%i"
    setlocal enabledelayedexpansion
    set "line=!line:%search%=%replace%!"
    >>"%textFile%" echo(!line!
    endlocal
)

但我返回的是5=Pippo.K=1=5

我该如何解决这个错误？

Answer 1

以下脚本构成了一个纯批处理文件解决方案。 假设它存储为repl-str.bat ，您需要为您的应用程序调用它：

repl-str.bat "%SettingFile%.txt" "Pippo.K=5" "Pippo.K=1" "%SettingFile%.txt"

这指定了输入文件%SettingFile%.txt 、文字和区分大小写的搜索字符串Pippo.K=5 、替换字符串Pippo.K=1以及与输入文件相同的输出文件%SettingFile%.txt （相关技术已取自此答案：批处理脚本以查找和替换文本文件中的字符串，而无需创建额外的输出文件来存储修改后的文件）。 如果没有给出输出文件，则结果输出到控制台（用于测试）。 如果给出了第五个命令行参数（任意值），则以区分大小写的方式进行搜索。

这是脚本repl-str.bat的代码：

@echo off
setlocal EnableExtensions DisableDelayedExpansion

set "FILE_I=%~1"
set "SEARCH=%~2"
set "REPLAC=%~3"
set "FILE_O=%~4"
set "CASE=%~5"
set "FLAG=%~6"
if not defined FILE_I exit /B 1
if not defined SEARCH exit /B 1
if not defined FILE_O set "FILE_O=con"
if defined CASE set "CASE=#"
if defined FLAG set "FLAG=#"

for /F "delims=" %%L in ('
    findstr /N /R "^" "%FILE_I%" ^& break ^> "%FILE_O%"
') do (
    set "STRING=%%L"
    setlocal EnableDelayedExpansion
    set "STRING=!STRING:*:=!"
    call :REPL RETURN STRING SEARCH REPLAC "%CASE%" "%FLAG%"
    >> "%FILE_O%" echo(!RETURN!
    endlocal
)

endlocal
exit /B


:REPL  rtn_string  ref_string  ref_search  ref_replac  case  flag
setlocal EnableDelayedExpansion
set "STR=!%~2!"
set "SCH=!%~3!"
set "RPL=!%~4!"
if "%~5"=="" (set "OPT=/I") else (set "OPT=")
if not defined SCH endlocal & set "%~1=" & exit /B 1
set "SCH_CHR=!SCH:~,1!"
if not "%~6"=="" set "SCH_CHR="
if "!SCH_CHR!"=="=" set "SCH_CHR=" & rem = terminates search string
if "!SCH_CHR!"==""^" set "SCH_CHR=" & rem " could derange syntax
if "!SCH_CHR!"=="%%" set "SCH_CHR=" & rem % ends variable expansion
if "!SCH_CHR!"=="^!" set "SCH_CHR=" & rem ! ends variable expansion
call :LEN SCH_LEN SCH
call :LEN RPL_LEN RPL
set /A RED_LEN=SCH_LEN-1
set "RES="
:LOOP
call :LEN STR_LEN STR
if not defined STR goto :END
if defined SCH_CHR (
    set "WRK=!STR:*%SCH_CHR%=!"
    if %OPT% "!WRK!"=="!STR!" (
        set "RES=!RES!!STR!"
        set "STR="
    ) else (
        call :LEN WRK_LEN WRK
        set /A DFF_LEN=STR_LEN-WRK_LEN-1,INC_LEN=DFF_LEN+1,MOR_LEN=DFF_LEN+SCH_LEN
        for /F "tokens=1,2,3 delims=," %%M in ("!DFF_LEN!,!INC_LEN!,!MOR_LEN!") do (
            rem set "RES=!RES!!STR:~,%%M!"
            if defined WRK set "WRK=!WRK:~,%RED_LEN%!"
            if %OPT% "!STR:~%%M,1!!WRK!"=="!SCH!" (
                set "RES=!RES!!STR:~,%%M!!RPL!"
                set "STR=!STR:~%%O!"
            ) else (
                set "RES=!RES!!STR:~,%%N!"
                set "STR=!STR:~%%N!"
            )
        )
    )
) else (
    if %OPT% "!STR:~,%SCH_LEN%!"=="!SCH!" (
        set "RES=!RES!!RPL!"
        set "STR=!STR:~%SCH_LEN%!"
    ) else (
        set "RES=!RES!!STR:~,1!"
        set "STR=!STR:~1!"
    )
)
goto :LOOP
:END
if defined RES (
    for /F delims^=^ eol^= %%S in ("!RES!") do (
        endlocal
        set "%~1=%%S"
    )
) else endlocal & set "%~1="
exit /B


:LEN  rtn_length  ref_string
setlocal EnableDelayedExpansion
set "STR=!%~2!"
if not defined STR (set /A LEN=0) else (set /A LEN=1)
for %%L in (4096 2048 1024 512 256 128 64 32 16 8 4 2 1) do (
    if defined STR (
        set "INT=!STR:~%%L!"
        if not "!INT!"=="" set /A LEN+=%%L & set "STR=!INT!"
    )
)
endlocal & set "%~1=%LEN%"
exit /B

基本上，这种方法采用搜索字符串的第一个字符并在输入文本中查找它。 在每次匹配时，检查整个搜索字符串是否出现。 如果是，则通过删除与搜索字符串所包含的字符一样多的字符来替换它，从而避免子字符串替换语法在搜索字符串包含=或搜索或替换字符串包含%或! .
但是，如果搜索字符串的第一个字符是= 、 " 、 %或! ，则方法不同，脚本检查搜索字符串的每个单个字符位置，然后降低整体性能。如果第六个给出了命令行参数（任意值），此（慢）模式是强制的。

Answer 2

批量变量子字符串替换确实有局限性。 处理字面等号就是其中之一。

powershell "(gc \"%textFile%\") -replace '%search%','%replace%'"

会工作。 PowerShell one-liner 是for /f循环的简单替代方案，没有这种限制。

---

如果您更喜欢for /F循环，如果您的文本文件是 ini 样式的文件，请尝试以下操作：

@echo off & setlocal

set "searchItem=Pippo.K"
set "searchVal=5"
set "newVal=1"
set "textFile=test.txt"

>"outfile.txt" (
    for /f "eol=; usebackq tokens=1* delims==" %%I in ("%textFile%") do (
        if /I "%%~I"=="%searchItem%" (
            if "%%~J"=="%searchVal%" (
                echo %%I=%newVal%
            ) else echo %%I=%%J
        ) else (
            if not "%%~J"=="" (echo %%I=%%J) else echo %%I
        )
    )
)
move /y "outfile.txt" "%textFile%"

请注意，如果您的文件中的任何项目具有空白值（例如valuename= ），除非您添加一些额外的逻辑，否则等号将被删除。

您也可以考虑使用此答案中的 ini.bat 。