如何检测字符串中单元格中是否存在单词？

Question

我有一些代码正在研究需要检测某个单元格中是否包含特定单词的地方，如果有，它将在相邻单元格中插入一个特定的字符串。 但是，在执行检测部分时遇到了问题！ 到目前为止，这就是我所拥有的。

Sub searchandpaste()
    Dim stopvar As Variant
    Dim i As Variant
    Dim j As Variant
    Dim k As Variant
    Dim TestVal1 As Variant
    Dim TestVal2 As Variant

    i = 0
    j = 0

    Do While stopvar = 0
        i = i + 1
        MsgBox ("Row " & i)
        MsgBox ("j equals " & j)
        'If the first cell is empty, that means we've hit the end of the worksheet, and it stops the do-while loop
        TestVal1 = Cells(i, 1)
        If TestVal1 = 0 Then
            stopvar = 1
        Else
            TestVal2 = Cells(i, 6)
            If IsEmpty(TestVal2) = True Then
                MsgBox ("Detected Empty Cell in Column 6")
                j = 1
            ElseIf TestVal2 = "XXXX" Then
                'This means we have a place we need to insert a value
                MsgBox ("Detected XXXX in Column 6")
                'We know at this point that in Cells(6,i) we have a value we need to insert. Thus, we need to search Cells(7,i) for key text
                If IsNumeric(Cells(7, j).Find("CYLINDER")) Or IsNumeric(Cells(7, j).Find("CYLINDERS")) Or IsNumeric(Cells(7, j).Find("CYL")) = True Then
                    MsgBox ("Detected the string CYLINDER")
                    j = j + 1
                    MsgBox ("j equals " & j)
                Else
                    MsgBox ("Did not detect the string CYLINDER")
                End If

            End If
        End If
    Loop
End Sub

我将在这里剪下重要部分。

'We know at this point that in Cells(6,i) we have a value we need to insert. Thus, we need to search Cells(7,i) for key text
If IsNumeric(Cells(7, j).Find("CYLINDER")) Or IsNumeric(Cells(7, j).Find("CYLINDERS")) Or IsNumeric(Cells(7, j).Find("CYL")) = True Then
    MsgBox ("Detected the string CYLINDER")
    j = j + 1
    MsgBox ("j equals " & j)
Else
    MsgBox ("Did not detect the string CYLINDER")
End If

我的意图是，这将在单元格（i，7）中的字符串中搜索单词Cylinder的不同变体，如果找到一个，它将返回TRUE或FALSE（false将是NAN，由IsNumeric捕获）并转为FALSE），让我知道它已检测到它。 但是，这似乎不起作用。

谁能指出我的错误？

有没有更好的方法来搜索字符串？ 就像，我可以只搜索“ CYL”并说它检测到其中任何一种变化吗？

Answer 1

您应该使用InStr函数进行如下比较：

If InStr(1, Cells(7, j), "CYLINDER") > 0 Or _
    InStr(1, Cells(7, j), "CYLINDERS") > 0 Or _
    InStr(1, Cells(7, j), "CYL") > 0 Then
        MsgBox ("Detected the string CYLINDER")
        j = j + 1
        MsgBox ("j equals " & j)
Else
    MsgBox ("Did not detect the string CYLINDER")
End If

有关此功能的更多信息，请访问MSDN， 网址为https://msdn.microsoft.com/zh-cn/library/office/gg264811%28v=office.15%29.aspx

为避免出现不同情况（如@Sgdva所建议），您可以选择以下几种方法：

If InStr(1, Cells(7, j), "CYLINDER", vbTextCompare) > 0 Or _
    InStr(1, Cells(7, j), "CYLINDERS", vbTextCompare) > 0 Or _
    InStr(1, Cells(7, j), "CYL", vbTextCompare) > 0 Then
        MsgBox ("Detected the string CYLINDER")
        j = j + 1
        MsgBox ("j equals " & j)
Else
    MsgBox ("Did not detect the string CYLINDER")
End If

要么

If InStr(1, UCase(Cells(7, j)), "CYLINDER") > 0 Or _
    InStr(1, UCase(Cells(7, j)), "CYLINDERS") > 0 Or _
    InStr(1, UCase(Cells(7, j)), "CYL") > 0 Then
        MsgBox ("Detected the string CYLINDER")
        j = j + 1
        MsgBox ("j equals " & j)
Else
    MsgBox ("Did not detect the string CYLINDER")
End If

要么

使用模块顶部的“ Option Compare Text ” Option Compare Text ，如此处指出的那样： https : //msdn.microsoft.com/en-us/library/office/gg278697.aspx

同时，您可能要考虑插入以下行：

Option Explicit

（用于良好的编码习惯）。

Answer 2

不确定您要用j变量完成什么，因为它似乎没有任何意义。 除了我似乎在您的代码中发现了错误以及Ralph提供的答案外。 Cells(7, j)应该是Cells(i, 7) 。 完整的代码是：

Sub searchandpaste()
    Dim stopvar As Variant
    Dim i As Variant
    Dim j As Variant
    Dim k As Variant
    Dim TestVal1 As Variant
    Dim TestVal2 As Variant

    i = 0
    j = 0

    Do While stopvar = 0
        i = i + 1
        MsgBox ("Row " & i)
        MsgBox ("j equals " & j)
        'If the first cell is empty, that means we've hit the end of the worksheet, and it stops the do-while loop
        TestVal1 = Cells(i, 1)
        If TestVal1 = 0 Then
            stopvar = 1
        Else
            TestVal2 = Cells(i, 6)
            If IsEmpty(TestVal2) = True Then
                MsgBox ("Detected Empty Cell in Column 6")
                j = 1
            ElseIf TestVal2 = "XXXX" Then
                'This means we have a place we need to insert a value
                MsgBox ("Detected XXXX in Column 6")
                'We know at this point that in Cells(6,i) we have a value we need to insert. Thus, we need to search Cells(7,i) for key text
                If InStr(LCase(Cells(i, 7)), "cyl") > 0 Then
                    MsgBox ("Detected the string CYLINDER")
                    j = j + 1
                    MsgBox ("j equals " & j)
                Else
                    MsgBox ("Did not detect the string CYLINDER")
                End If

            End If
        End If
    Loop
End Sub