Neo4j-根据关系属性查找两个节点之间的最短路径

Question

我正在尝试确定是否有某种方法可以根据关系求和得出两个节点之间的最短距离，例如以下示例： neo4j image example

上图的代码：

CREATE (some_point_1:Point {title:'Some Point 1'})
CREATE (some_point_2:Point {title:'Some Point 2'})
CREATE (some_point_3:Point {title:'Some Point 3'})
CREATE (some_point_4:Point {title:'Some Point 4'})
CREATE (some_point_5:Point {title:'Some Point 5'})
CREATE (some_point_6:Point {title:'Some Point 6'})

CREATE (some_point_1)-[:distance {value:100}]->(some_point_2)
CREATE (some_point_2)-[:distance {value:150}]->(some_point_4)
CREATE (some_point_1)-[:distance {value:200}]->(some_point_3)
CREATE (some_point_3)-[:distance {value:300}]->(some_point_4)
CREATE (some_point_2)-[:distance {value:500}]->(some_point_5)
CREATE (some_point_4)-[:distance {value:300}]->(some_point_5)
CREATE (some_point_5)-[:distance {value:300}]->(some_point_6)
CREATE (some_point_6)-[:distance {value:300}]->(some_point_1)

在此示例中，最短路径应为：some_point_1> some_point_2> some_point_4> some_point_5（100 + 150 + 300 = 550）

Cypher可能会发生这种情况吗？

Answer 1

该shortestPath在Cypher支架功能不考虑关系性质的积累，所以这样的：

MATCH (start:Point {title: 'Some Point 1'}), (end:Point {title: 'Some Point 5'})
MATCH p=shortestPath((start)-[:distance*]->(end))
RETURN p

会发现从最短路径start到end基于路径的数量关系。

您可以减少距离的总和：

MATCH (start:Point {title: 'Some Point 1'}), (end:Point {title: 'Some Point 5'})
MATCH p=(start)-[:distance*]->(end)
WITH p,reduce(s = 0, r IN rels(p) | s + r.value) AS dist
RETURN p, dist ORDER BY dist DESC

但是这里的问题是，您需要计算从start到end所有路径的总距离。 为了提高效率，您想使用图搜索算法，例如Dijkstra的算法或A *，两者均在Neo4j的Java API中实现 。

在Neo4j 3.0中，这些算法通过APOC过程库在Cypher中公开。 安装APOC后，您可以从Cypher调用该过程：

MATCH (start:Point {title: 'Some Point 1'}), (end:Point {title: 'Some Point 5'})
CALL apoc.algo.dijkstra(start, end, 'distance', 'value') YIELD path, weight
RETURN path, weight

Answer 2

Cypher具有shortestPath（）函数，该函数与谓词和一些反复试验结合起来可能会满足您的要求。

但是为了节省时间，使用neo4j APOC Procedures更加容易，该过程包括一个加权的dijkstra最短路径算法，应该最适合您的需求。

我还没有使用过，但是我认为语法（在startNode和endNode上匹配之后，使用关系的名称和用于权重的属性）类似于

CALL apoc.algo.dijkstra(startNode, endNode, 'distance', 'value') 
YIELD path, weight

至于考虑方向，Wiki文档并未直接说出来，但我认为<或>添加到关系标签的适当末端，所以'distance>'可能是更正确的参数，如果您希望它尊重方向。