指向CUDA中对象的指针数组的指针

Question

我遵循了这个问题和此链接提供的指导， 这些指导涉及将指针数组传递给设备并返回的概念，但是当指针指向对象时，我似乎在为我的具体情况苦苦挣扎。 请参阅下面的示例代码，其中为了简洁起见，我已删除了错误检查。

// Kernel
__global__ void myKernel(Obj** d_array_of_objs)
{
    // Change the scalar of each object to 5
    // by dereferencing device array to get 
    // appropriate object pointer.
    *d_array_of_objs->changeToFive();    <--------- SEE QUESTION 4
}

// Entry point
int main()
{

    /********************************/
    /* INITIALISE OBJ ARRAY ON HOST */
    /********************************/

    // Array of 3 pointers to Objs
    Obj* h_obj[3];
    for (int i = 0; i < 3; i++) {
        h_obj[i] = new Obj();       // Create
        h_obj[i]->scalar = i * 10;  // Initialise
    }

    // Write out
    for (int i = 0; i < 3; i++) {
        std::cout << h_obj[i]->scalar << std::endl;
    }


    /**************************************************/
    /* CREATE DEVICE VERSIONS AND STORE IN HOST ARRAY */
    /**************************************************/

    // Create host pointer to array-like storage of device pointers
    Obj** h_d_obj = (Obj**)malloc(sizeof(Obj*) * 3);    <--------- SEE QUESTION 1
    for (int i = 0; i < 3; i++) {
        // Allocate space for an Obj and assign
        cudaMalloc((void**)&h_d_obj[i], sizeof(Obj));
        // Copy the object to the device (only has single scalar field to keep it simple)
        cudaMemcpy(h_d_obj[i], &(h_obj[i]), sizeof(Obj), cudaMemcpyHostToDevice);
    }

    /**************************************************/
    /* CREATE DEVICE ARRAY TO PASS POINTERS TO KERNEL */
    /**************************************************/

    // Create a pointer which will point to device memory
    Obj** d_d_obj = nullptr;
    // Allocate space for 3 pointers on device at above location
    cudaMalloc((void**)&d_d_obj, sizeof(Obj*) * 3);
    // Copy the pointers from the host memory to the device array
    cudaMemcpy(d_d_obj, h_d_obj, sizeof(Obj*) * 3, cudaMemcpyHostToDevice);


    /**********
     * After the above, VS2013 shows the memory pointed to by d_d_obj 
     * to be NULL <------- SEE QUESTION 2.
     **********/


    // Launch Kernel
    myKernel <<<1, 3>>>(d_d_obj);

    // Synchronise and pass back to host
    cudaDeviceSynchronize();
    for (int i = 0; i < 3; i++) {
        cudaMemcpy(&(h_obj[i]), h_d_obj[i], sizeof(Obj), cudaMemcpyDeviceToHost);     <--------- SEE QUESTION 3
    }

    // Write out
    for (int i = 0; i < 3; i++) {
        std::cout << h_obj[i]->scalar << std::endl;
    }

    return 0;
}

所以问题是：

1. 如果上面的SEE QUESTION 1指示的行为指针分配了主机内存，并且一旦我在后续循环中使用cudaMalloc分配了设备内存，则h_d_obj指向的指针将被设备地址覆盖，这是否意味着我已经分配了主机3 Obj*内存现在没有指向它的指针？

2. 当我测试返回的状态但显然不能正确复制地址时，为什么cudaMemcpy成功？ 我期望h_d_obj和d_d_obj的内存地址的“数组”相同，因为它们应指向设备地址空间中的同一Obj 。

3. 在第SEE QUESTION 3 ，假设我在问题2中是对的。我还希望能够使用h_d_obj或d_d_obj从设备检索Obj对象，因为区别仅在于是否取消引用主机指针来访问我可以在cudaMemcpy方法中做到的指向Obj的设备指针或设备指针，对吗？ 如果使用写入的内容，则复制成功，但是h_obj[0]的指针已损坏，并且我无法写出数据。

4. 在SEE QUESTION 4 ，为什么我不能取消引用Obj**以获取Obj*然后使用->运算符来调用设备方法？ 编译器抱怨说它不是指向Obj*类型的指针，而实际上它是一个Obj*告诉我的事实。

Answer 1

首先，如果提供完整的代码（包括Obj类的定义），将很方便。 根据您对代码的检查和一些猜测，我提供了一个。

其次，您在这里的许多困惑似乎是使用C（或C ++）中的指针的不那么酥脆的工具。 将CUDA API与主机和设备之间的双指针结构（ ** ）一起使用需要清晰的了解和可视化情况的能力。

如果上面的SEE QUESTION 1指示的行为指针分配了主机内存，并且一旦我在后续循环中使用cudaMalloc分配了设备内存，则h_d_obj指向的指针将被设备地址覆盖，这是否意味着我已经分配了主机3 Obj *的内存现在没有指向它的指针？

否。通过malloc操作建立了h_d_obj （即，赋予了有意义的值）。 h_d_obj您没有做任何修改h_d_obj的值。

当我测试返回的状态但显然不能正确复制地址时，为什么cudaMemcpy成功？ 我期望h_d_obj和d_d_obj的内存地址的“数组”相同，因为它们应指向设备地址空间中的同一Obj。

到目前为止，我认为您的代码没有任何问题。 h_d_obj的值（以前）是由malloc建立的，其数值是主机内存中的地址。 d_d_obj的值由cudaMalloc ，其数值是设备内存中的地址。 从数字上讲，我希望它们会有所不同。

在第3个问题上，假设我在问题2中是对的。我还希望能够使用h_d_obj或d_d_obj从设备检索Obj对象，因为区别仅在于我是否取消引用主机指针来访问我可以在cudaMemcpy方法中做到的指向Obj的设备指针或设备指针，对吗？ 如果使用写入的内容，则复制成功，但是h_obj [0]上的指针已损坏，并且我无法写出数据。

没有。 您不能在主机代码中取消引用设备指针， 即使它是cudaMemcpy的参数。 作为cudaMemcpy操作中的源或目标，这是合法的：

h_d_obj[i]

这是不合法的：

d_d_obj[i]

原因是为了获得实际的目标地址，在第一种情况下，我必须取消引用主机指针（即访问主机上的内存位置），而在第二种情况下，必须取消引用设备指针。 从主机代码中，我可以检索h_d_obj[i]的内容。 我不允许尝试在主机代码中检索d_d_obj[i]的内容（而cudaMemcpy的参数操作是主机代码）。 d_d_obj的值可用作主机代码中的目标。 d_d_obj[i]不能。

在SEE QUESTION 4行上，为什么不能取消引用Obj **以获取Obj *，然后使用->运算符来调用设备方法？ 编译器抱怨说它不是指向对象类型的指针，而实际上它是一个Obj *告诉我的事实。

编译器很烦您，因为您不了解所使用的各种运算符（ * ， -> ）之间的运算顺序。 如果添加括号以标识正确的顺序：

(*d_array_of_objs)->changeToFive(); 

然后，编译器将不会对此表示反对（尽管如下所示，我会做些微的不同）。

这是您的代码的修改后的版本，其中添加了Obj定义，对内核进行了少许更改，以便独立线程可以在独立对象上工作，并且还进行了其他一些修复。 您的代码大部分是正确的：

$ cat t1231.cu
#include <iostream>

class Obj{

  public:
  int scalar;
  __host__ __device__
  void changeToFive() {scalar = 5;}
};

// Kernel
__global__ void myKernel(Obj** d_array_of_objs)
{
    // Change the scalar of each object to 5
    // by dereferencing device array to get
    // appropriate object pointer.
    int idx = threadIdx.x+blockDim.x*blockIdx.x;
    // (*d_array_of_objs)->changeToFive();  //  <--------- SEE QUESTION 4 (add parenthesis)
    d_array_of_objs[idx]->changeToFive();
}

// Entry point
int main()
{

    /********************************/
    /* INITIALISE OBJ ARRAY ON HOST */
    /********************************/

    // Array of 3 pointers to Objs
    Obj* h_obj[3];
    for (int i = 0; i < 3; i++) {
        h_obj[i] = new Obj();       // Create
        h_obj[i]->scalar = i * 10;  // Initialise
    }

    // Write out
    for (int i = 0; i < 3; i++) {
        std::cout << h_obj[i]->scalar << std::endl;
    }


    /**************************************************/
    /* CREATE DEVICE VERSIONS AND STORE IN HOST ARRAY */
    /**************************************************/

    // Create host pointer to array-like storage of device pointers
    Obj** h_d_obj = (Obj**)malloc(sizeof(Obj*) * 3); //    <--------- SEE QUESTION 1
    for (int i = 0; i < 3; i++) {
        // Allocate space for an Obj and assign
        cudaMalloc((void**)&h_d_obj[i], sizeof(Obj));
        // Copy the object to the device (only has single scalar field to keep it simple)
        cudaMemcpy(h_d_obj[i], &(h_obj[i]), sizeof(Obj), cudaMemcpyHostToDevice);
    }

    /**************************************************/
    /* CREATE DEVICE ARRAY TO PASS POINTERS TO KERNEL */
    /**************************************************/

    // Create a pointer which will point to device memory
    Obj** d_d_obj = NULL;
    // Allocate space for 3 pointers on device at above location
    cudaMalloc((void**)&d_d_obj, sizeof(Obj*) * 3);
    // Copy the pointers from the host memory to the device array
    cudaMemcpy(d_d_obj, h_d_obj, sizeof(Obj*) * 3, cudaMemcpyHostToDevice);


    /**********
     * After the above, VS2013 shows the memory pointed to by d_d_obj
     * to be NULL <------- SEE QUESTION 2.
     **********/


    // Launch Kernel
    myKernel <<<1, 3>>>(d_d_obj);

    // Synchronise and pass back to host
    cudaDeviceSynchronize();
    for (int i = 0; i < 3; i++) {
        cudaMemcpy(h_obj[i], h_d_obj[i], sizeof(Obj), cudaMemcpyDeviceToHost);  //   <--------- SEE QUESTION 3  remove parenthesis
    }

    // Write out
    for (int i = 0; i < 3; i++) {
        std::cout << h_obj[i]->scalar << std::endl;
    }

    return 0;
}
$ nvcc -o t1231 t1231.cu
$ cuda-memcheck ./t1231
========= CUDA-MEMCHECK
0
10
20
5
5
5
========= ERROR SUMMARY: 0 errors
$

h_d_obj和d_d_obj可能会有所帮助：

HOST                               |    DEVICE
h_d_obj-->(Obj *)-------------------------->Obj0<---(Obj *)<----|
          (Obj *)-------------------------->Obj1<---(Obj *)     |
          (Obj *)-------------------------->Obj2<---(Obj *)     |
                                   |                            |
d_d_obj---------------------------------------------------------|
HOST                               |    DEVICE

您可以使用主机代码或cudaMemcpy操作访问上图左侧（HOST）上的任何数量（位置）。 不允许您在主机代码的右侧访问任何数量（位置）。