创建接口的匿名实例

Question

我是vb.net的新手，并且具有接受带类型的接口的函数，并且我想创建该接口的匿名实例作为方法参数。

接口

Public Interface MessageHandler(Of T)

    Sub Handle(Message As T)

End Interface

---

我不确定我是否正确地描述了我的问题，所以这是我想要的Java语言：

接口

public interface MessageHandler<T> {

    public abstract void handle(T message);

}

方法调用

function(new MessageHandler<Type>() {

    public void handle(Type message) {
        //Do Something
    }

});

Answer 1

您不能在.NET中创建接口的匿名实现。 您必须有一个具体的实现，但是可以很容易地将其隐藏起来并提供相同的匿名化。

我已经通过.NET修改了您的命名约定，但是在这里是：

Public Interface IMessageHandler(Of T)
    Sub Handle(message As T)
End Interface

Public NotInheritable Class MessageHandler
    Private Sub New()
    End Sub
    Private Class AnonymousMessageHandler(Of T)
        Implements IMessageHandler(Of T)
        Private _handler As Action(Of T)
        Public Sub New(handler As Action(Of T))
            _handler = handler
        End Sub
        Public Sub Handle(message As T) Implements IMessageHandler(Of T).Handle
            Dim h = _handler
            If h IsNot Nothing Then
                h(message)
            End If
        End Sub
    End Class

    Public Shared Function Create(Of T)(handler As Action(Of T)) As IMessageHandler(Of T)
        Return New AnonymousMessageHandler(Of T)(handler)
    End Function
End Class

或者，在C＃中：

public interface IMessageHandler<T>
{
    void Handle(T message);
}

public static class MessageHandler
{
    private class AnonymousMessageHandler<T> : IMessageHandler<T>
    {
        private Action<T> _handler;
        public AnonymousMessageHandler(Action<T> handler)
        {
            _handler = handler;
        }
        public void Handle(T message)
        {
            _handler?.Invoke(message);
        }
    }

    public static IMessageHandler<T> Create<T>(Action<T> handler)
    {
        return new AnonymousMessageHandler<T>(handler);
    }
}

您可以这样称呼它（在VB.NET中）：

MessageHandler.Create(Of Integer)(Sub (x) Console.WriteLine(x)).Handle(42)