如何实现属性特定的模板而没有冗余

Question

我熟悉如何使用按如下所示禁用属性的模板（例如，禁用foo的存在）：

<xsl:template match="something[@foo]">
<xsl:template match="something[not(@foo)]">

但是，如果这些模板的大部分内容相同，是否存在一种更好的方式仍然使用模板，因为社区似乎更喜欢它们？ 或者只是使用xsl:choose的解决方案。 显然最好不要编写必须在两个模板中都必须维护的重复代码。

编辑：这是我特定的模板集：

<xsl:template match="item[not(@format)]">
  <td class="{current()/../@name}_col status_all_col">
  <xsl:value-of select="current()"/>
  <xsl:value-of select="@units"/>
  </td>
</xsl:template>

<xsl:template match="item[@format]">
  <td class="{current()/../@name}_col status_all_col">
  <xsl:value-of select="format-number(current(), @format)"/>
  <xsl:value-of select="@units"/>
  </td>

</xsl:template>

这是我目前使用的选择：

<xsl:template match="item">
  <td class="{current()/../@name}_col status_all_col">
  <xsl:choose>
    <xsl:when test="@format">
      <xsl:value-of select="format-number(current(), @format)"/>
    </xsl:when> 
    <xsl:otherwise>
      <xsl:value-of select="current()"/>
    </xsl:otherwise>
  </xsl:choose>
  <xsl:value-of select="@units"/>
  </td>
</xsl:template>

Answer 1

在这种情况下，我肯定会使用xsl:choose 。

---

只是为了演示了如何使用模板，而无需重复的代码：

<xsl:template match="item">
    <td class="{../@name}_col status_all_col">
        <xsl:apply-templates select="." mode="format"/>
        <xsl:value-of select="@units"/>
    </td>
</xsl:template>

<xsl:template match="item[not(@format)]" mode="format">
    <xsl:value-of select="."/>
</xsl:template>

<xsl:template match="item[@format]" mode="format">
    <xsl:value-of select="format-number(., @format)"/>
</xsl:template>

但是我看不出这样做会有什么好处。 相反，它患有GOTO综合症 。

---

顺便说一句，这可能不是最好的例子，因为我相信提供一个空字符串作为format-number()函数的第二个参数将导致按原样返回数字。

因此，您可以只使用一个模板来匹配所有模板：

<xsl:template match="item">
    <td class="{../@name}_col status_all_col">
        <xsl:value-of select="format-number(current(), @format)"/>
        <xsl:value-of select="@units"/>
    </td>
</xsl:template>