从Elixir Process打印到控制台

Question

因此，我开始玩Elixir，我想制作两个模块。 一个会提示您输入消息，然后将消息发送到另一个程序，该程序将确认收到消息，这将导致第一个程序打印出该消息。

好吧，我有问题。

发件人如下：

defmodule PracticeCaller do
    def start do
        spawn(&sloop/0) 
    end

    def sloop do
        pid = :erlang.spawn(&PracticeServer.start/0)
        message = IO.gets "Enter a message:"
        send(pid, {self, message})
        receive do
            {_caller, reply} -> IO.puts "#{reply}"
        end
        sloop
    end
end

接收者在这里：

defmodule PracticeServer do
    def start do
        spawn(&loop/0)
    end

    defp loop do
        receive do
          {caller, "kill"} -> send(caller, {self, "Process Dead"})
                Process.exit(self, :kill)
            {caller, _} -> send(caller, {self, "Thank you for your message!"})      
        end

        loop    
    end

end

我的第一个问题是，当我开始发送者循环时，终端会提示我输入一条消息，但不会打印收到的消息。

其次，当我输入“ kill”时，终端冻结，因为我不确定如何处理：kill响应。

对解决这些问题有帮助吗？

Answer 1

第一个问题是：

pid = :erlang.spawn(&PracticeServer.start/0)

并且PracticeServer.start/0调用再次spawn的事实。 这意味着此处的pid并不是指运行PracticeServer.loop/0的进程，而是指产生了PracticeServer.loop/0并立即退出的进程。

如果我更改：

pid = :erlang.spawn(&PracticeServer.start/0)

只是：

pid = PracticeServer.start

一些事情开始起作用：

Enter a message:hello
Thank you for your message!
Enter a message:world
Thank you for your message!

但：

Enter a message:kill
Thank you for your message!

这是因为IO.gets/1包含尾随换行符，这意味着PracticeServer.loop/0的{caller, "kill"}模式永远不会匹配。

可以通过以下方法解决此问题：

message = IO.gets "Enter a message:"

至

message = IO.gets("Enter a message:") |> String.trim_trailing

现在：

Enter a message:kill
Process Dead
Enter a message:kill
Process Dead

另一个问题是您当前正在泄漏进程。 无需重用衍生服务器，而是为每条消息均产生一个新服务器。 同样，处理可能被“杀死”的递归receive的惯用方式是在您希望进程终止时不进行递归调用。 这是一些重构的代码：

defmodule PracticeCaller do
  def start do
    spawn(fn -> loop(PracticeServer.start) end)
  end

  def loop(server) do
    message = IO.gets("Enter a message: ") |> String.trim_trailing
    send(server, {self, message})
    receive do
      {_caller, reply} ->
        IO.puts "#{reply}"
        # Only continue if process is not dead.
        # Comparing against strings is usually not idiomatic, you may want to
        # change that.
        if reply != "Process Dead" do
          loop(server)
        end
    end
  end
end

defmodule PracticeServer do
  def start do
    spawn(&loop/0)
  end

  def loop do
    receive do
      {caller, "kill"} ->
        send(caller, {self, "Process Dead"})
      {caller, _} ->
        send(caller, {self, "Thank you for your message!"})      
        loop    
    end
  end
end

PracticeCaller.start
:timer.sleep(:infinity)

请注意，即使在发送“ kill”之后，这也不会停止VM。 如果这只是一个脚本，则可以在消息为“ Process Dead”时将:erlang.halt添加到PracticeCaller.loop/1 ，以立即停止VM。