如何在Perl中生成给定单词的建议列表？

Question

我创建了一个包含单词列表的自定义词典。 现在的计划是在Perl中创建一个程序，它接受一个单词并生成一个单词列表（比如说其中5个），它们与该词典中给定的单词最接近（词汇顺序）。 现在我想知道是否有可用的模块可以帮助我做到这一点。 如果没有，那么我该如何实现这样的目标呢？ 提前致谢

Answer 1

我猜你正在研究自动校正功能。 我研究了类似的功能， Text :: SpellChecker对我帮助很大。 该模块在后台使用aspell或hunspell ，因此也提供多语言支持。 它检查拼写错误的单词并提供相同的建议。

use Text::SpellChecker;
($Text::SpellChecker::pre_hl_word,
 $Text::SpellChecker::post_hl_word) = (qw([ ]));

my $checker = Text::SpellChecker->new(text => "Foor score and seven yeers ago");

while (my $word = $checker->next_word) {
    print $checker->highlighted_text, 
        "\n", 
        "$word : ",
        (join "\t", @{$checker->suggestions}),
        "\nChoose a new word : ";
    chomp (my $new_word = <STDIN>);
    $checker->replace(new_word => $new_word) if $new_word;
}

希望这可以帮助。

Answer 2

是的， Search :: Dict将在字典文件中有效地找到单词或最接近的单词。 该程序将找到输入单词周围的单词。

#!/usr/bin/perl
use strict;
use warnings;
use autodie;
use v5.10;

use Search::Dict;
use POSIX qw(ceil floor);

my $target = shift;
my $Window_Size = 5;
my @window;

open my $fh, "/usr/share/dict/words";

# Find the spot in the file where the word
# is >= our word.
# Use dictinoary order and ignore case.
my $pos = look $fh, $target, 1, 1;

# Add the next words
for(1..ceil($Window_Size/2)) {
    my $word = <$fh>;
    chomp $word;

    redo if $word eq $target;

    push @window, $word;
}

# Read the previous block of words
my $string;
seek $fh, $pos - 256, 0;
read $fh, $string, 256;
my @previous_words = split /\n/, $string;

# Add them to our list at the front.
for(1..floor($Window_Size/2)) {
    unshift @window, pop @previous_words;
}

say join ", ", @window;

例如...

$ perl ~/tmp/test.plx foot
fooster, foosterer, footage, footback, football

边缘情况就像你的单词是“A”或“Zyzzogeton”一样留下来作为练习。