在为Reader r编写Applicative实例时如何编写<*>

Question

我坚持在Haskell Book中练习，“第22章读者”。 练习说“实施阅读器的应用”，它给出了以下内容：

{-# LANGUAGE InstanceSigs #-}

newtype Reader r a =
  Reader { runReader :: r -> a }

instance Applicative (Reader r) where 
  pure :: a -> Reader r a
  pure a = Reader $ ???

  (<*>) :: Reader r (a -> b) -> Reader r a -> Reader r b
  (Reader rab) <*> (Reader ra) = Reader $ \r -> ???

我也写了一个Functor实例后编写了pure （我编写了Functor实例，因为否则GHC抱怨“没有实例(Functor (Reader r)) …来自实例声明的超类在实例声明中'Applicative (Reader r)' “）：

{-# LANGUAGE InstanceSigs #-}

newtype Reader r a =
  Reader { runReader :: r -> a }

instance Functor (Reader r) where
  fmap f (Reader x) = Reader (f . x)

instance Applicative (Reader r) where
  pure :: a -> Reader r a
  pure a = Reader $ \_ -> a

  (<*>) :: Reader r (a -> b) -> Reader r a -> Reader r b
  (Reader rab) <*> (Reader ra) = Reader $ \r -> ???

但我坚持了??? 部分。

该书给出了以下提示：

我们为您启动了apply函数的定义，我们将描述您需要做什么并编写代码。 如果您打开上面适用的Reader类型，您将获得以下内容。

 <*> :: (r -> a -> b) -> (r -> a) -> (r -> b) -- contrast this with the type of fmap fmap :: (a -> b) -> (r -> a) -> (r -> b) 

那有什么区别？ 区别在于，与fmap不同， apply也采用r类型的参数。

这样做。

是的，但如何做到这一点？ 使用打字的孔 ，编译器告诉我???的类型 必须是b 。 但是我仍然无法看到如何构造一个带有r的lambda表达式并返回b类型的东西，给出了rab和ra 。

Answer 1

我们打网球。 看看你在范围内的作品，

rab :: r -> (a -> b)
ra :: r -> a
r :: r

和b的目标类型，你可以看到你可以获得一个b的唯一方法是将rab应用于两个参数。

Reader rab <*> Reader ra = Reader $ \r -> rab _ _

现在，第一个洞的类型为r ，你只有一个r在范围内。

Reader rab <*> Reader ra = Reader $ \r -> rab r _

剩余孔具有类型的a 。 你在范围内唯一的a是ra的返回值，

Reader rab <*> Reader ra = Reader $ \r -> rab r (ra _)

并且ra的论证必须是r ，为此你再次只有一个选择。

Reader rab <*> Reader ra = Reader $ \r -> rab r (ra r)

请注意， rab和ra都接受r作为参数。 组合Reader计算中的所有步骤都可以访问相同的环境。

顺便提一下，这个定义使<*>等同着名的S组合子 （ pure是K ）。