SAS-使用宏以Excel格式输出结果

Question

我使用以下代码将结果导出为ex​​cel文件。 但是，每次结果都以文件类型输出。 我必须手动将其类型更改为excel。 我尝试将.xls放在&from.&&memname&i ，但是SAS无法识别这种格式。 我认为可能的原因是.x ，但是我不知道如何解决此问题。

%macro tradetime(sourcelib=,from=,going=,dir=);
proc sql noprint;  /*read datasets in a library*/
  create table mytables as
  select *
  from dictionary.tables
  where libname = &sourcelib
  order by memname ;

  select count(memname) 
  into:obs 
  from mytables;

  %let obs=&obs.;

  select memname
  into : memname1-:memname&obs.
  from mytables;
quit;

  %do i=1 %to &obs.;

  ods tagsets.excelxp file= "&Dir\&&memname&i" /*output the results to target file*/
  style=XLsansPrinter;
  ods listing close;
  ods results off;
  proc univariate data= &from.&&memname&i;
  var  time_l_ ;  
  run;
  quit;

  ods tagsets.excelxp close;
  ods listing ;
  ods results on;
%end;
%mend;

%tradetime(sourcelib='AXP',from=AXP.,going=AXP.,dir=D:\Data\description);

Answer 1

您可能在宏变量终止符上遇到了问题。 如果你试试：

&Dir\&&memname&i.xls

那不管用。 点是宏变量终止符，实际上，在您的情况下，您需要多个，因为您使用的是两个& -所以&[i]. 是一个宏变量，然后有&[memname&i.]. 作为第二个（第一个&消失）。 因此，您需要：

&Dir\&&memname&i...xls

创建.xls扩展名。

需要注意的是tagsets.excelxp 不创建本地Excel文件。 它创建excel可读的xml文件。 因此，如果将.xls放在excel上，excel会给您带来一些麻烦（在某些情况下，它将打开，在某些情况下，它将拒绝，具体取决于您的设置和excel版本）。 如果支持.xlsx文件并且具有SAS 9.4 TS1M1或更高版本，则最好使用ods excel 。