我可以在PL / SQL块中使用REGEXP_LIKE作为IF的条件吗

Question

我正在尝试创建一个功能，该功能旨在遍历一棵组织单位的树，并根据它们在树状结构中的等级以及它们在我们的Intranet页面上显示的天气来过滤掉一些。 该函数的输入是起始单元的ORG_UNIT_ID，该标志用于显示我们是否应该关心Intranet标志以及逗号分隔的级别列表。 例如“ 2,3”。 我试图在循环内结合使用REGEXP_LIKE和ELSEIF来运行树，直到遇到第一个合格的父单元。

T_STOP是循环的控制变量。 R_ORG_UNIT_OVER用于查询上述单元上的元数据。 在循环的第一遍中，这将是作为函数输入传递的单元上方的单位。

游标定义：

CURSOR C_ORG_UNIT_OVER(V_ORG_UNIT_ID ORG_UNIT.ORG_UNIT_ID%TYPE) IS
  SELECT  ORUI.ORG_UNIT_ID
  ,       ORUI.ORG_LEVEL
  ,       ORUI.SHOW_ON_INTRANET
FROM    ORG_UNIT ORUI
JOIN    ORG_UNIT_PARENT OUPA ON ORUI.ORG_UNIT_ID=OUPA.ORG_UNIT_ID_PARENT
WHERE   OUPA.ORG_UNIT_ID = V_ORG_UNIT_ID;

循环中失败的代码段：

IF R_ORG_UNIT_OVER.SHOW_ON_INTRANET = 'N' THEN
  T_ORG_UNIT_ID := R_ORG_UNIT_OVER.ORG_UNIT_ID;
ELSEIF REGEXP_LIKE (P_SKIP_LEVEL, '(^|,)' || R_ORG_UNIT_OVER.ORG_LEVEL || '($|,)') THEN
  T_ORG_UNIT_ID := R_ORG_UNIT_OVER.ORG_UNIT_ID;
ELSE
  T_STOP := 'Y';
END IF;

但是，此代码始终在REGEXP_LIKE符号上引发PLS-00103错误。 在PL / SQL IF / ELSEIF块中用作条件而不是在常规查询中使用REGEXP_LIKE时，是否存在某种限制或替代方式？

Answer 1

是的你可以。

declare 
    testvar varchar2(20) := 'Kittens';
begin
    if regexp_like(testvar, '^K') then
        dbms_output.put_line(testvar || ' matches ''^K''');
    end if;
end;

Kittens matches '^K'

PL/SQL procedure successfully completed.

包括一些测试数据，我将尝试查看哪些功能无法正常工作。 例如，

declare 
    p_skip_level number := 2;
    org_level number := 3;
begin
    if regexp_like (p_skip_level, '(^|,)' || org_level || '($|,)')
    then
        dbms_output.put_line('Matched');
    else
        dbms_output.put_line('Not matched');
    end if;
end;

Answer 2

PL / SQL使用ELSIF而不是ELSEIF 。 通过编辑，您的代码确实会得到您所描述的错误； 这样做不会：

IF R_ORG_UNIT_OVER.SHOW_ON_INTRANET = 'N' THEN
  T_ORG_UNIT_ID := R_ORG_UNIT_OVER.ORG_UNIT_ID;
ELSIF REGEXP_LIKE (P_SKIP_LEVEL, '(^|,)' || R_ORG_UNIT_OVER.ORG_LEVEL || '($|,)') THEN
  T_ORG_UNIT_ID := R_ORG_UNIT_OVER.ORG_UNIT_ID;
ELSE
  T_STOP := 'Y';
END IF;