使用 CMake 将 Qt DLL 复制到 Windows 上的可执行目录

Question

CMake 新手，我很难理解如何使用生成器表达式。 我正在尝试使用add_custom_command创建一个构建后命令以将 Qt DLL 复制到可执行目录。

在Qt5WidgetsConfig.cmake我可以看到它为 Qt5::Widgets 目标创建了不同的属性以引用 DLL，具体取决于当前活动的配置。 IMPORTED_LOCATION_DEBUG或IMPORTED_LOCATION_RELEASE 。 我希望能够使用$<CONFIG:Debug>生成器表达式作为if()的条件，但这不起作用。

我的 CMakeLists.txt：

# minimum version required for proper support of C++11 features in Qt
cmake_minimum_required(VERSION 3.1.0)

set(CMAKE_CONFIGURATION_TYPES Debug;Release)

# project name and version
project(TPBMon VERSION 0.0.0.1)

# Qt5 libs
find_package(Qt5Widgets REQUIRED)

# run Qt's MOC when needed
set(CMAKE_AUTOMOC ON)

add_executable(
    tpbmon
    src/main.cpp
    src/mainwindow.hpp
    src/mainwindow.cpp
)
target_link_libraries(tpbmon Qt5::Widgets)
set_target_properties(
    tpbmon
    PROPERTIES
    RUNTIME_OUTPUT_DIRECTORY ${PROJECT_SOURCE_DIR}/bin
)
if(WIN32)
    if($<CONFIG:Debug>)
        get_target_property(WIDGETDLL Qt5::Widgets IMPORTED_LOCATION_DEBUG)
    else($<CONFIG:Debug>)
        get_target_property(WIDGETDLL Qt5::Widgets IMPORTED_LOCATION_RELEASE)
    endif($<CONFIG:Debug>)
    add_custom_command(
        TARGET tpbmon POST_BUILD
        COMMAND ${CMAKE_COMMAND} -E copy ${WIDGETDLL} $<TARGET_FILE_DIR:tpbmon>
    )
endif(WIN32)

Answer 1

通过修改add_custom_command调用来自己想出来

add_custom_command(
    TARGET tpbmon POST_BUILD
    COMMAND ${CMAKE_COMMAND} -E copy_if_different
        $<TARGET_FILE:Qt5::Widgets>
        $<TARGET_FILE_DIR:tpbmon>
)

这是一个令人惊奇的事情，一个良好的睡眠后，一个新的视角可以做到。 ;）

Answer 2

您可以使用windeployqt程序，它是Qt二进制版本的一部分。 它将扫描您的二进制文件并收集所有使用过的Qt DLL，插件和QML模块。 它可以通过add_custom_command(TARGET target_name POST_BUILD ...)签名包装在CMake中作为构建后事件。

Answer 3

将来您可以将所有 Qt5 依赖项添加到您的可执行文件夹中：

 find_package(Qt5 COMPONENTS Core Gui Widgets)
 ...   
 add_custom_command(TARGET MyQtProj POST_BUILD
        COMMAND ${CMAKE_COMMAND} -E copy_if_different $<TARGET_FILE:Qt5::Core> $<TARGET_FILE_DIR:MyQtProj>
        COMMAND ${CMAKE_COMMAND} -E copy_if_different $<TARGET_FILE:Qt5::Gui> $<TARGET_FILE_DIR:MyQtProj>
        COMMAND ${CMAKE_COMMAND} -E copy_if_different $<TARGET_FILE:Qt5::Widgets> $<TARGET_FILE_DIR:MyQtProj>
        )