使用For循环填充组合框

Question

对于项目，我想用可变数量的选项填充用户窗体上的组合框。 选项的数量取决于工作表前面给出的数量。 用户将输入一个值，并为所有这些值分配名称。 可能只有2个名字，但也可能有10个名字。

我希望组合框使用给定的值（名称的数量）用存储在不同位置的名称填充自身。 我的当前代码如下所示，但它给了我以下编译错误，然后选择.AddItem部分作为错误源。

编译错误：预期函数或变量

Private Sub UserForm_Initialize()
'Sheet1.Range("A1") contains the value for the amount of names

If Sheet1.Range("A1") = 0 Or Sheet1.Range("A1") = "" Then
    'Do Nothing
Else
    With ComboBox1
        For n = 1 To Sheet1.Range("A1")
            'col determines the column in which the names are found
            'The first name is in column 2, the next in column 10, etc.
            col = 2 + 8 * (n - 1)
            .AddItem = Sheet2.Cells(5, col)
        Next
    End With
End If

End Sub

希望我的问题很清楚。 我觉得我已经很接近答案了，但是我无法在任何地方使用Google找到答案。

Answer 1

.Additem是一种方法，而不是可以设置的属性。 您必须提供该项目作为参数，即

.AddItem Sheet2.Cells(5, col)

Answer 2

或者，您可以使用ComboBox对象的List属性，并通过数组填充它，如下所示：

Private Sub UserForm_Initialize()
    With Sheet1.Range("A1") 'reference the cell that contains the value for the amount of names
        If .Value > 0 Then Me.ComboBox1.List = GetValues(.Value) '<--| fill ComboBox via its 'List' property passing it the array returned by GetValues() function 
    End With
End Sub

Function GetValues(nCols As Long) As Variant
    Dim n As Long

    ReDim vals(1 To nCols) As Variant '<--| size the array to match the amount of names passed in
    For n = 1 To nCols
        vals(n) = Sheet2.Cells(5, 2 + 8 * (n - 1)) '<--| fill the array: the first name is in column 2, the next in column 10, etc.
    Next
    GetValues = vals '<--| return the filled array
End Function

这也将使您的代码更“模块化”