Prolog - 在列表中创建累积重复项？

Question

我有一个列表L给我，我的任务是创建累积重复，取决于我想要多少。

我有列表[a,b,c,d]例如，并希望第一个元素重复4次（可选），然后每个后续元素必须像前一个+ 1一样重复。

假设我的谓词叫做list_copy(L,N,R) ， L = [a,b,c,d]和K = 2应该是：

?- list_copy([a,b,c,d],2,R).
R = [a,a,b,b,b,c,c,c,c,d,d,d,d,d]

我设法创建了一个通用代码，用于复制列表两次：

dupl([],[]).
dupl([O|U],[O,O|U1]) :- dupl(U,U1). 

根据我在第二行中放置了多少O ，我得到了许多重复。

我的问题是：我如何将第三个变量实现为累积计数器，以获得理想的结果？

Answer 1

当你必须逐个“计算”东西时，考虑使用succ/2 。 它具有良好的属性，它可以双向工作，并在使用succ(X, 0)调用它时失败。

首先，执行“累积重复”的谓词：

cum_dup([], _, []).
cum_dup([X|Xs], N, Ys) :-
    repeat_n(X, N, Ys, Back),
    succ(N, N1),
    cum_dup(Xs, N1, Back).

这使用谓词repeat_n/4 ，它接受一个元素，一个非负整数，并重复该元素。 它在列表的后面留下一个“洞”，您可以使用cum_dup/3填充结果的其余部分。 这是repeat_n/4的直接实现：

repeat_n(_, 0, L, L).
repeat_n(X, N, [X|Xs], Rest) :-
    succ(N0, N),
    repeat_n(X, N0, Xs, Rest).

这将为您提供所需的结果：

?- cum_dup([a,b,c,d], 2, R).
R = [a, a, b, b, b, c, c, c, c, d, d, d, d, d] ;
false

它留下了一个无害的选择点。 有太多方法可以使repeat_n/4不会留下不必要的选择点：

• 使用CLP（FD）
• 用切口
• 使用条件（if-then-else）
• 使用结构而不是整数

只举一个例子：

repeat_n(X, N, L, Back) :-
    length(Ns, N),
    repeat_n_(Ns, X, L, Back).

repeat_n_([], _, L, L).
repeat_n_([_|Ns], X, [X|Xs], L) :-
    repeat_n_(Ns, X, Xs, L).

在这里，您（ab）不使用整数计数，而是使用该长度的列表。

我猜你自己可以考虑一下，如果你真的需要，可以问另一个问题。

Answer 2

---编辑---使用succ/2修改，如Boris所建议（谢谢！）。

我想你可以使用一个帮助器子句。 与以下示例中的list_copy_h/4类似

list_copy_h([], _, _, []).

list_copy_h([_ | Tin], 0, Num, Lout) :-
  succ(Num, Np1),
  list_copy_h(Tin, Np1, Np1, Lout).

list_copy_h([H | Tin], Count, Num, [H | Tout]) :-
  succ(Cm1, Count),
  list_copy_h([H | Tin], Cm1, Num, Tout).

list_copy(Lin, Num, Lout) :-
  list_copy_h(Lin, Num, Num, Lout).

这个想法是使用减少到零的计数器（第二个参数）。 当为零时，输入列表的头部被放电，并且循环再次以输入列表的以下元素开始，但增加计数器的起始值。 第三个参数是起始值。