Perl正则表达式按顺序查找包含关键字的字符串

Question

我正在学习Perl。 我想按此顺序查找3个关键字的所有匹配项：文本中的keyword1 ， keyword2和keyword3 。 keyword1和keyword3是可选的。 关键字之间最多可以包含6个字。 这是Perl中的代码：

#!/usr/bin/perl
$reg="(keyword1)*\W*(?:\w+\W+){0,6}?(keyword2)\W*(?:\w+\W+){0,6}?(keyword3)*";
$content="some words before keyword1 optional word here then keyword2 again optional words then keyword3 others words after.";
while ($content=~m/$reg/g) {
    print "$&\n";
} 

我只想在此提取子字符串keyword1 optional word here then keyword2 again optional words then keyword3提取keyword1 optional word here then keyword2 again optional words then keyword3但是我得到了keyword2 。 谢谢。

Answer 1

首先， "\\w"产生字符串w ，而"\\W"产生字符串W

$ perl -wE'say "\w\W"'
Unrecognized escape \w passed through at -e line 1.
Unrecognized escape \W passed through at -e line 1.
wW

您需要转义反斜杠（ "\\\\W" ）或使用qr// （ qr/\\W/ ）。

---

我很确定该模式还有其他问题。 我将从头开始。

假设k1和k3都是独立可选的，则需要：

qr/
    (?: \b k1 \W+
        (?: \w+ \W+ ){0,6}?
    )?

    \b k2 \b

    (?: 
        (?: \W+ \w+ ){0,6}?
        \W+ k3 \b
    )?
/x

边界（ \\b ）一词可确保我们不匹配abck2def或abck1 k2 k3def 。

---

以上是低效的。

以以下正则表达式模式为例：

(?: x y )? x z

它可以匹配以下字符串：

xyxz
xz

请注意，两者都是如何以x开头的？ 这意味着更好的模式（即执行较少回溯的模式）将是

x (?: y x )? z    

上面的答案中有几个这种反模式的例子。 因此，让我们进行重构。

qr/
    \b
    (?: k1 \W+ (?: \w+ \W+ ){0,6}? \b )?
    k2 \b
    (?: \W+ (?: \w+ \W+ ){0,6}? k3 \b  )?
/x

现在我们有了高效的东西。

---

在上述模式中，请注意第二个\\b是多余的。 因此，让我们摆脱它。

如果我们在末尾添加\\b ，则第三和第四\\b变得多余。

应用这些简化后，我们得到：

qr/
    \b
    (?: k1 \W+ (?: \w+ \W+ ){0,6}? )?
    k2
    (?: \W+ (?: \w+ \W+ ){0,6}? k3 )?
    \b
/x

---

就个人而言，除了优化之外，我非常不喜欢非贪婪修饰符。 此外，使用它们中的两个通常是一个巨大的红旗，表明该模式中存在错误。 例如，模式可以匹配k1 k1 k2 ，但这可能不是理想的。

为了消除它们，我们需要确保第一个\\w+与k1或k2不匹配。 这可以通过更换来实现

\b \w+ \b

与

(?! \b k1 \b ) (?! \b k2 \b ) \b \w+ \b

同样，我们将常见的前缀排除在外以获得：

\b (?! (?: k2 | k3 ) \b ) \w+ \b

同样，我们需要确保第二个\\w+与k2或k3不匹配。

通过这些更改，我们得到：

qr/
    \b
    (?: k1 \W+ (?: (?! (?: k1 | k2 ) \b ) \w+ \W+ ){0,6} )?
    k2
    (?: \W+ (?: (?! (?: k2 | k3 ) \b ) \w+ \W+ ){0,6} k3 )?
    \b
/x

---

复杂？ 是。 更好的解决方案可能始于将流分解为单词和非单词令牌。 这样做的好处是我们不再需要担心边界。

my @tokens = split(/(\W+)/, $content, -1);

然后，检查阵列中的图案。 由于正则表达式引擎特别擅长做到这一点，因此我们可以如下利用它：

my $tokens =
   join '',
      map {
         ($_ % 2) ? "W"
         : $words[$_] eq "k1" ? 1
         : $words[$_] eq "k2" ? 2
         : $words[$_] eq "k3" ? 3
         : "w"                      # Non-key word
      }
         0..$#tokens;

while ($tokens =~ /(?: 1 W (?: w W ){0,6} )? 2 (?: W (?: w W ){0,6} 3 )?/xg) {
   say join('', @tokens[ $-[0] .. $+[0] - 1 ]);
}

鉴于@tokens始终为单词，非单词，单词，非单词等形式，我们还可以使用以下形式：

my $words =
   join '',
      map {
         ($_ % 2) ? ""              # We just want to look at the words
         : $words[$_] eq "k1" ? 1
         : $words[$_] eq "k2" ? 2
         : $words[$_] eq "k3" ? 3
         : "w"                      # Non-key word
      }
         0..$#tokens;

while ($words =~ /(?: 1 w{0,6} )? 2 (?: w{0,6} 3 )?/xg) {
   say join('', @tokens[ $-[0] * 2 .. ( $+[0] - 1 ) * 2 ]);
}