将XML文件拆分为多个

Question

之前可能已经有人问过这个问题，但是我有一个XML文件，需要将其拆分为单个文件。

该文件是：

<?xml version="1.0" encoding="UTF-8"?>
<invoices>
    <invoice>
        <data>

        </data>
    </invoice>
    <invoice>
        <data>

        </data>
    </invoice>
</invoices>

我有我的代码将其拆分为：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0" exclude-result-prefixes="xsl">
    <xsl:output method="xml" encoding="UTF-8" omit-xml-declaration="no" indent="yes"/>
    <xsl:template match="/">
        <tosplit>
            <xsl:for-each-group select="//invoice" group-by="ceiling(position() div 1)">
                <xsl:apply-templates select="/" mode="copy">
                    <xsl:with-param name="currentgroup" select="current-group()"/>
                </xsl:apply-templates>
            </xsl:for-each-group>
        </tosplit>
    </xsl:template>
    <xsl:template match="@*|node()" mode="copy">
        <xsl:param name="currentgroup"/>
        <xsl:copy>
            <xsl:apply-templates select="@*|node()" mode="copy">
                <xsl:with-param name="currentgroup" select="current-group()"/>
            </xsl:apply-templates>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="invoices" mode="copy">
        <xsl:param name="currentgroup"/>
        <xsl:copy>
            <xsl:apply-templates select="@*" mode="copy"/>
            <xsl:apply-templates select="$currentgroup" mode="copy"/>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

但是，这并不能解决问题。 我希望每个文件看起来像

<?xml version="1.0" encoding="UTF-8"?>
<tosplit>
   <invoices>
      <invoice>
         <data>

         </data>
      </invoice>
   </invoices>
</tosplit>

任何帮助将不胜感激。

Answer 1

如果您可以访问xSLT 3.0处理器，例如oXygen中的Saxon 9 PE或EE或XMLSpy 2017中的Altova的Raptor，那么您所需要做的就是

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:math="http://www.w3.org/2005/xpath-functions/math"
    exclude-result-prefixes="xs math"
    version="3.0">

    <xsl:mode on-no-match="shallow-skip" streamable="yes"/>

    <xsl:strip-space elements="*"/>
    <xsl:output indent="yes"/>

    <xsl:template match="invoice">
        <xsl:result-document href="invoice-split{position()}.xml">
            <xsl:copy-of select="snapshot(.)/root()"/>
        </xsl:result-document>
    </xsl:template>

</xsl:stylesheet>

为每个invoice元素创建一个结果文档。

Answer 2

首先让我们看看为什么您的代码不起作用

<xsl:template match="/">
        <tosplit>
            <xsl:for-each-group select="//invoice" group-by="ceiling(position() div 1)">
                <xsl:apply-templates select="/" mode="copy">
                    <xsl:with-param name="currentgroup" select="current-group()"/>
                </xsl:apply-templates>
            </xsl:for-each-group>
        </tosplit>
    </xsl:template>

我真的不知道您对分组属性有何想法​​。 如果X是一个整数（与position（）一样），则ceiling(X div 1)将返回X不变。 因此，它与group-by =“ position（）”相同，并且由于每个项目的位置都不同，因此每个项目将进入一个单独的组。 这意味着您的代码是一种复杂的工作方式：

<xsl:template match="/">
    <tosplit>
        <xsl:for-each select="//invoice" >
             <xsl:apply-templates select="/" mode="copy">
                 <xsl:with-param name="currentgroup" select="."/>
             </xsl:apply-templates>
        </xsl:for-each>
   </tosplit>
</xsl:template>

反过来，它无法实现无法自然完成的任何事情

<xsl:template match="/">
    <tosplit>
        <xsl:apply-templates select="//invoice" mode="copy"/>
   </tosplit>
</xsl:template>

基本上，您不需要进行任何分组，并且从问题陈述中无需进行任何分组，因此很难看到此代码的全部含义。

同时，您说您想为每张发票生成一个文件，但是您的代码没有尝试生成多个输出文件。