Gradle未发布自定义jar工件

Question

我有一个gradle构建，必须将预构建的jar文件作为工件发布。 由于某种原因，它没有被捡起。 这是复制它的简化版本：

文件夹内容：

settings.gradle
build.gradle
some.jar

settings.gradle：

rootProject.name = 'some'

的build.gradle：

apply plugin: 'base'
apply plugin: 'maven-publish'

group = 'foo.bar'
version = '1.0'

task copyPrebuilt(type: Copy) {
  from(projectDir) {
    include 'some.jar'
    rename 'some', "some-$version"
  }
  into distsDir
}

artifacts {
  // should be 'archives'?
  // http://stackoverflow.com/questions/39068090/gradle-archives-artifacts-not-populated-to-default-configuration
  'default' (file("$distsDir/some-${version}.jar")) {
    name 'some'
    type 'jar'
    builtBy copyPrebuilt
  }
}

some-1.0.jar不会被复制到~/.m2/repository/foo/bar/some/1.0由gradle publishToMavenLocal

有什么线索吗？

Answer 1

获得发布内容的最简单方法是定义发布对象：

apply plugin: 'base'
apply plugin: 'maven-publish'

group = 'foo.bar'
version = '1.0'

task copyPrebuilt(type: Copy) {
    from(projectDir) {
        include 'some.jar'
        rename 'some', "some-$version"
    }
    into buildDir
}

publishToMavenLocal.dependsOn copyPrebuilt

publishing {
    publications {
        prebuilt(MavenPublication) {
            artifact file("$buildDir/some-${version}.jar")
        }
    }
}

此代码使publishToMavenLocal任务将some-1.0.jar安装到本地maven存储库。