如何在Tcl中实现队列和优先级队列？

Question

我必须在不使用任何库的情况下在Tcl中实现队列或优先级队列。

我试图写下面的代码。 请帮助我以更好的方式在Tcl / Tk中实现队列。

创建节点

// crearting node element of queue  

proc createNode {name cost} {
            namespace eval $name [subst {     
                variable cost $cost  
                variable this $name   
            }]  

职能

proc ${name}::getCost {} {  
            variable cost  
            return $cost  
        }  
      return $name  
     } 

删除队列

 proc deQueue name {  
           #upvar 1 $name queue  
           set queue $name  
           set res [lindex $queue 0]  
           set queue [lrange $queue 1 end]; # remove the first element  
           set res; # return the value  
        }  

队列插入

  proc enQueue {newNode name} { 
            #upvar 1 $name queue  
            set queue $name  
            set queue [concat $newNode $queue]  
        }  

创建队列

 proc makeQueue {n g } {   
            set queue [list [createNode $n $g ]] 
            return $queue   
        }   

Answer 1

一个简单的队列实现：

proc enqueue {name item} {
    upvar 1 $name queue
    lappend queue $item
}

proc dequeue name {
    upvar 1 $name queue
    set queue [lassign $queue item]
    return $item
}

% enqueue a foo
% set item [dequeue a]

一个简单的优先级队列：

proc enpqueue {name prio item} {
    upvar 1 $name queue
    lappend queue [list $prio $item]
    set queue [lsort -decreasing -integer -index 0 $queue]
}

proc depqueue name {
    upvar 1 $name queue
    set queue [lassign $queue prioitem]
    return [lindex $prioitem 1]
}

% enpqueue a 10 foo
% enpqueue a 40 bar
% set item [depqueue a]
bar

队列或优先级队列唯一需要的是列表和添加/删除接口。

如果要将结构化数据存储在队列中，请使该item成为数据元组：

set item [list "Smith, John" 42 1500]

或字典：

set item [list name "Smith, John" age 42 foo 1500]

文档： lappend ， lassign ， lindex ， list ， lsort ， proc ， return ， set ， upvar

Answer 2

队列是具有两个（关键）操作的抽象数据结构： add和get （并且empty测试也很常见）。 它们内部非常复杂，因此最好考虑使用TclOO对象作为其实现：

oo::class create Queue {
    variable q
    constructor {} {
        set q {}
    }
    method add {item} {
        lappend q $item
        return
    }
    method empty {} {
        expr {[llength $q] == 0}
    }
    method get {} {
        if {[my empty]} {
            return -code error "queue is empty"
        }
        set q [lassign $q item]
        return $item
    }
}

优先级队列与队列类似，不同之处在于它们也具有优先级并按该优先级排序。 有效实现它们的技巧不是对每个add或get进行排序，而是仅在必要时进行排序。 （或者您可以使用适当的平衡树，但是它们很复杂。）

oo::class create PriorityQueue {
    variable q sorted
    constructor {} {
        set q {}
        set sorted 1
    }
    method add {item priority} {
        lappend q $item $priority
        set sorted 0
        return
    }
    method empty {} {
        expr {[llength $q] == 0}
    }
    method get {} {
        if {[my empty]} {
            return -code error "queue is empty"
        }
        if {!$sorted} {
            # You might want other options here, depending on what "priority" means
            set q [lsort -stride 2 -index 1 -integer $q]
            set sorted 1
        }
        set q [lassign $q item priority]
        return $item
    }
}

使用这些数据结构非常简单：

# Instantiate
set myq [PriorityQueue new]
# Add some values
$myq add "The quick brown fox" 12
$myq add "The lazy dog" 34
# Drain the queue
while {![$myq empty]} {
    puts [$myq get]
}
# Get rid of it now we're done
$myq destroy