VBA正则表达式

Question

我试图循环浏览电子邮件正文并将电子邮件转发到其他收件箱。 我的正则表达式将前后的任何4-6个字符编号与空格匹配，但是问题是电子邮件中包含了日期，因此它也选择了四个字符编号“ 2017”。 正则表达式是什么省略了“ 2017”而只取所有其他4-6个字符数字。 这是我的代码。

Option Explicit
Public Sub Forward(Item As Outlook.MailItem)
    Dim M1 As MatchCollection
    Dim M As Match
    Dim Reg1 As Object
    Dim myForward As Object

    Set Reg1 = New RegExp

    With Reg1
        .Pattern = "(\s[0-9]{4,6}\s)"
        .Global = True
    End With

    If Reg1.Test(Item.Body) Then
        Set M1 = Reg1.Execute(Item.Body)
        For Each M In M1
            Debug.Print M.SubMatches(0) ' Immediate Window

            '// allows for multiple matches in the message body
            Item.Subject = M.SubMatches(0) & "; " & Item.Subject

        Next
    End If

    Item.Save

    Set myForward = Item.Forward
    myForward.Recipients.Add "xxxxx@gmail.com"
    myForward.Display
End Sub

这是我转发的新电子邮件的主题输出。
体育-，2017体育-，2017体育-5556我只想能够捕捉到“体育-5556”

Answer 1

您可以使用否定的前瞻（请参阅MSDN：“正则表达式语法（脚本）” ）从匹配项中排除某些字符串。

这是我的写法：

Option Explicit

Public Sub Forward(Item As Outlook.MailItem)
    Dim DigitsExp As New RegExp
    Dim Matches As MatchCollection, Match As Match

    If Item Is Nothing Then Exit Sub

    DigitsExp.Pattern = "\s(?!2017\s)([0-9]{4,6})\s"
    DigitsExp.Global = True

    Set Matches = DigitsExp.Execute(Item.Body)
    For Each Match in Matches
        Debug.Print Match.SubMatches(0)
        Item.Subject = Match.SubMatches(0) & "; " & Item.Subject
    Next
    If Not Item.Saved Then Item.Save

    With Item.Forward
        .Recipients.Add "xxxxx@gmail.com"
        .Display
    End With
End Sub

其中\\s(?!2017\\s)([0-9]{4,6})\\s匹配不是2017任何4-6位数字子字符串，而(?!2017\\s)是排除它的否定前瞻。