将变量名用于局部数组的参数派生范围

Question

使用fortran，我在以下情况下运行：我有多个局部变量，它们的大小是从输入参数中以某种冗长的方式得出的，例如

program pbounds 
contains 
  subroutine sbounds(x) 
    integer,intent(in) :: x(:,:)
    integer y1(size(x,1)/3,size(x,2)/2)
    integer y2(size(x,1)/3,size(x,2)/2)
    integer y3(size(x,1)/3,size(x,2)/2)
    ! ... do some stuff 
  end subroutine sbounds
end program pbounds

当我不断重复size表达式时，这似乎过于冗长。 另外，当需要更改时（例如，事实证明我需要y4并将size(x,1)/3更改为size(x,1)/4 ，对于看起来不太像的实际代码整洁，很容易错过以前的变量之一。

在我的实际代码中，其他示例包括声明的大小来自冗长的，重复的复合类型字段，例如

type(sometype), intent(in) :: obj
real :: arr1(obj%subfield%nmax, obj%subfield%nmax, obj%subfield%xmax, 3, 3)
real :: arr2(obj%subfield%nmax, obj%subfield%xmax)
...

是否可以不使用预处理器宏或可分配数组来定义大小表达式的名称？

我尝试过的东西

使用可分配变量，我们可以将局部变量用作大小表达式的名称，但是我们将局部数组的声明分成两行。

program pboundsx
contains
  subroutine sboundsx(x)
    integer,intent(in) :: x(:,:)
    integer,allocatable :: y1(:,:),y2(:,:),y3(:,:)
    integer s(2)
    s = [ size(x,1)/3, size(x,2)/2 ]
    allocate(y1(s(1),s(2)))
    allocate(y2(s(1),s(2)))
    allocate(y3(s(1),s(2)))
    ! ... do some stuff 
  end subroutine sboundsx
end program pboundsx

使用预处理器宏，我们可以给size表达式起一个名字，但这是以增加多个预处理器行为代价的，这会干扰缩进模式。

program pboundsm
contains
  subroutine sboundsm(x)
    integer,intent(in) :: x(:,:)
#define s1 (size(x,1)/3)
#define s2 (size(x,2)/2)
    integer y1(s1,s2)
    integer y2(s1,s2)
    integer y3(s1,s2)
#undef s1
#undef s2
    ! ... do some stuff     
  end subroutine sboundsm
end program pboundsm

通过第二个子例程，我们可以将sizes设为显式参数，但这可能是最冗长和晦涩的解决方案。 更重要的是，考虑到在现实世界中代码“ x”不是唯一的参数。

program pboundss
contains
  subroutine sboundss(x)
    integer, intent(in) :: x(:,:)
    call sboundss2(x,size(x,1)/3,size(x,2)/2)
  end subroutine sboundss
  subroutine sboundss2(x,s1,s2)
    integer, intent(in) :: x(:,:), s1, s2
    integer y1(s1,s2), y2(s1,s2), y3(s1,s2)
  end subroutine sboundss2
  ! ... do stuff
end program pboundss

如果允许混合使用声明和初始化，则解决方案将很简单，但事实并非如此：

program pboundsv
contains
  subroutine sboundsv(x)
    integer,intent(in) :: x(:,:)
    integer s1 = size(x,1)/3, s2 = size(x,2)/3  ! INVALID DECLARATION
    integer y1(s1,s2), y2(s1,s2), y3(s1,s2)
    ! ... do stuff
  end subroutine sboundsv
end program pboundsv

Answer 1

如果编译器允许（*），则可以选择将子例程主体完全包含在一个块中（=新作用域），并混合声明和赋值：

program pboundsv
contains
    subroutine sboundsv(x)
        integer,intent(in) :: x(:,:)
        integer s1, s2
        s1 = size(x,1)/3 ; s2 = size(x,2)/3
        block
        integer y1(s1,s2), y2(s1,s2), y3(s1,s2)
        ! ... do stuff
        endblock
    endsubroutine
end program

（*）但是，这是Fortran> 95，并且Oracle Studio fortran 12.5仍然无法编译（非常可悲）...（gfortran和ifort似乎还可以）。

Answer 2

部分解决方案-虽然规格说明不能依赖于局部变量（**）的值，但它们可以取决于其他局部变量的先前规格。 例如：

subroutine sbounds(x) 
  integer,intent(in) :: x(:,:)
  integer y1(size(x,1)/3,size(x,2)/2)
  integer y2(size(y1,1),size(y1,2))
  integer y3(size(y1,1),size(y1,2))
  ! ... do some stuff 
end subroutine sbounds

...

type(sometype), intent(in) :: obj
real :: arr1(obj%subfield%nmax, obj%subfield%nmax, obj%subfield%xmax, 3, 3)
real :: arr2(size(arr1,1), size(arr1,3))

在某些情况下，这可以使声明的逻辑结构更清晰-“此变量的此维的范围与该变量的此维的范围相同”，这可能是与代码阅读者更相关的信息而不是计算范围的特定表达式。

**请注意，对规范和常量表达式的各种限制才是最后一块代码的真正问题。 在Fortran中，您可以很高兴地将声明与初始化和其他声明混合在一起（它们只是规范语句），而您不能做的就是将规范语句与可执行语句混合在一起（除了块构造等）。 规范表达式不能依赖于局部变量的值，部分原因是否则很难确保确定性的排序，而常量表达式则不能依赖于任何变量的值，因为常量表达式被认为是常量（并且能够在编译时评估）。