用新值替换字符串

Question

我正在尝试操作一个巨大的文件（+5.000.000 条记录），因此我可以替换例如第 8 列的值。

If $8 = 1 replace it with success
if $8 = 2 replace it with check
if $8 = null replace with undefined

这是一段由,字符分隔的数据：

"APPLICATION_ID","ORIGIN_ID","SERVICE_ID","PROVIDER_ID","RATING_ID","ATO","DATE","USER_TYPE","ESTATUS","OPERATION_ID"

"3","2","424","5020","1058","3017292917","30/11/2016 01:14:25 a.m.","1","2004","14804862360104011458"

我要替换的字段是位于$8 USER_TYPE

我试过这个，但它没有替换值：

awk '{if($8 = 1) print $1, $2, $3, $4, $5, $6, $7, "success", $9, $10}' input_file

我怎样才能做到这一点？

Answer 1

@sandatomo：尝试（未经测试）：

awk -F, -vs1="\"" 'NR>1{gsub(/\"/,"",$8);if($8==1){sub(/.*/,s1 "success" s1,$8)};if($8==2){sub(/.*/,s1 "check" s1,$8)};if($8=="null"){sub(/.*/,s1 "undefined" s1,$8)};print}' OFS=, Input_file

编辑：现在也添加一种非单衬形式的解决方案。

awk -F, -vs1="\"" 'NR>1{
                                gsub(/\"/,"",$8);
                                if($8==1){
                                                sub(/.*/,s1 "success" s1,$8)
                                         };
                                if($8==2){
                                                sub(/.*/,s1 "check" s1,$8)
                                         };
                                if($8=="null"){
                                                sub(/.*/,s1 "undefined" s1,$8)
                                              };
                                print
                       }
                  ' OFS=,  Input_file

EDIT2：我测试了我的代码以前的代码，它没有字段分隔符为“，”所以现在编辑它。

EDIT3：以上解释。

awk  -F, -vs1="\"" 'NR>1{                                  ##### Setting Field separator as comma(,). Creating a variable named s1 whose value is a quote("). Then Checking here if current line number is greater than 1.
                                                           ##### If above condition is TRUE then all following statements will be executing.
                gsub(/\"/,"",$8);                          ##### substituting all quotes(") in $8 now.
        if($8==1){                                 ##### Check if 8th field value is 1, if yes then it will execute following statement.
                sub(/.*/,s1 "success" s1,$8)     ##### substitute everything in $8 with  s1 "success" s1
                 };
                if($8==2){                                 ##### Similarly like above checking if $8's value is 2
                sub(/.*/,s1 "check" s1,$8)       ##### Then substitute the $8's value with s1 "check" s1
                 };  
                if($8=="null"){                            ##### checking if $8's value is "null" here
                sub(/.*/,s1 "undefined" s1,$8)   ##### substituting the complete value of $8 with s1 "undefined" s1.
                      };
        print                                      ##### printing the whole line now.
         }
    '   OFS=,  Input_file                                  ##### Setting output field separator as a comma. Then mentioning the Input_file here.

Answer 2

你可以尝试这样的事情：

awk  'BEGIN {OFS=FS=",";r["\"\""] = "\"undefined\""; r["\"1\""]= "\"success\""; r["\"2\""]="\"check\""} {if($8 in r ) $8 = r[$8]} 1' input_file

解释

• BEGIN部分在r设置了一个替换映射。 例如r["\\"1\\""]= "\\"success\\""; 是文字标记"1" （带有 qoutes 的 1！）到文字值"success" （也包括引号！）的映射
• 另外FS和OFS在BEGIN部分设置为使用逗号作为输入和输出分隔符
• r定义之后的部分包括测试字段$8的值是否是映射中的键，如果是，则字段$8被替换为映射r中为该键定义的值
• 如果$8列中有未映射的值，问题不是 100% 清楚，因此请将此作为您自己实验的起点

Answer 3

这是一个较短的单行：

$ awk 'BEGIN{FS=OFS=",";a[1]="success";a[2]="check"} {gsub(/"/,"",$8)} $8 in a{$8=a[$8]} 1' input.txt

打破评论：

BEGIN {
  FS=OFS=","       # set our field separators
  a[1]="success"   # populate an array with replacement values
  a[2]="check"
}

{
  gsub(/"/,"",$8)   # remove quotes in field 8, for easier processing
}

$8 in a {           # check to see if field 8 is a member of our array
  $8=a[$8]          # replace field 8 with the contents of the array at that index
}

1                   # print the line

如果保留每个字段周围的引号很重要，您可以通过将分配替换为包含它们的sprintf()来实现：

  $8=sprintf("\"%s\"",a[$8])

请记住，awk 只知道您的字段分隔符，而不知道您的引号。 如果您的字段在引用字段中包含逗号，awk 会将其视为字段分隔符。 您可以在 awk 脚本的顶部使用以下内容为此类事件添加保护：

NF != 10 { print "ERROR: wrong number of fields in line",NR > "/dev/stderr"; exit(1) }